media-sound/cadence: bump to 0.9.2, addy python 3.10 & 3.11, eapi8, updated live

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 95 insertions, 2 deletions

diff --git a/media-sound/cadence/Manifest b/media-sound/cadence/Manifest
index 4b62b9742a88..2542a4389457 100644
--- a/media-sound/cadence/Manifest
+++ b/media-sound/cadence/Manifest
@@ -1 +1,2 @@
 DIST cadence-0.9.1.tar.gz 2202272 BLAKE2B 0f96a3eadc90540ef455e3b9c9abe1b8dc0d912936642c77e52a3704367f06e870b4cbe0bee78482436b9b099063c66b0b04007e8905b7eaf213d6b2f9aa08d1 SHA512 daa9df947f0198522172451ec3d2a0e138de5245d4fa849c89ae17fc141388467bdb2e5b1ed191d1db372f4d1c02a8f1c32458c20b893d413af8fdce72ee9219
+DIST cadence-0.9.2.tar.gz 2202164 BLAKE2B a5422e4d74618e2e45d9c6f275393a6e918783fc37d60a54142725aa54e691435c41f76dd0346fae7684c452988b07a18d817902abd917dbceaff5fb4aaa6c47 SHA512 d8a1b52c361e3e18a193d1c283bb69abe18ce667b554fc53cb9b752d92747269145144ae512895ffbb5df76efe8671cfc0782f29e59d0d7cd3d97c97240bdecf
diff --git a/media-sound/cadence/cadence-0.9.2.ebuild b/media-sound/cadence/cadence-0.9.2.ebuild
new file mode 100644
index 000000000000..826035d06617
--- /dev/null
+++ b/media-sound/cadence/cadence-0.9.2.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit python-single-r1 xdg desktop
+
+DESCRIPTION="Collection of tools useful for audio production"
+HOMEPAGE="https://kxstudio.linuxaudio.org/Applications:Cadence"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/falkTX/Cadence.git"
+else
+	SRC_URI="https://github.com/falkTX/Cadence/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/Cadence-${PV}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="a2jmidid pulseaudio opengl"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+CDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/PyQt5[dbus,gui,opengl?,svg,widgets,${PYTHON_USEDEP}]
+	')
+	media-sound/jack_capture
+	virtual/jack
+	a2jmidid? ( media-sound/a2jmidid[dbus] )
+	pulseaudio? ( || ( media-sound/pulseaudio-daemon[jack] <media-sound/pulseaudio-15.99.1[daemon(+),jack] ) )
+"
+RDEPEND="${CDEPEND}"
+DEPEND="${CDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.9.1-fix-clang.patch
+)
+
+src_prepare() {
+	sed -i -e "s/python3/${EPYTHON}/" \
+		data/cadence \
+		data/cadence-aloop-daemon \
+		data/cadence-jacksettings \
+		data/cadence-logs \
+		data/cadence-render \
+		data/cadence-session-start \
+		data/catarina \
+		data/catia \
+		data/claudia \
+		data/claudia-launcher || die "sed failed"
+
+	default
+}
+
+src_compile() {
+	myemakeargs=(PREFIX="${EPREFIX}/usr"
+		SKIP_STRIPPING=true
+	)
+
+	emake "${myemakeargs[@]}"
+}
+
+src_install() {
+	emake PREFIX="${EPREFIX}/usr" DESTDIR="${ED}" install
+
+	python_fix_shebang "${ED}"
+
+	# Clean up stuff that shouldn't be installed
+	rm -rf "${ED}"/etc/X11/xinit/xinitrc.d/61cadence-session-inject
+	rm -rf "${ED}"/etc/xdg/autostart/cadence-session-start.desktop
+	rm -rf "${ED}"/usr/share/applications/*.desktop
+
+	if use !pulseaudio; then
+		rm -rf "${ED}"/usr/bin/cadence-pulse2{jack,loopback}
+		rm -rf "${ED}"/usr/share/cadence/pulse2{jack, loopback}
+	fi
+	# Depend on ladish which is not in the tree
+	rm -rf "${ED}"/usr/bin/claudia{,-launcher}
+	rm -rf "${ED}"/usr/share/cadence/icons/claudia-hicolor/
+
+	# Replace desktop entries with QA issues with these
+	make_desktop_entry cadence Cadence cadence "AudioVideo;AudioVideoEditing;Qt"
+	make_desktop_entry catia Catia catia "AudioVideo;AudioVideoEditing;Qt"
+	make_desktop_entry catarina Catarina catarina "AudioVideo;AudioVideoEditing;Qt"
+}
diff --git a/media-sound/cadence/cadence-9999.ebuild b/media-sound/cadence/cadence-9999.ebuild
index 0100e16f1a3f..826035d06617 100644
--- a/media-sound/cadence/cadence-9999.ebuild
+++ b/media-sound/cadence/cadence-9999.ebuild
@@ -1,9 +1,9 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-PYTHON_COMPAT=( python3_{8,9} )
+PYTHON_COMPAT=( python3_{8..11} )
 inherit python-single-r1 xdg desktop
 
 DESCRIPTION="Collection of tools useful for audio production"