media-sound/musescore: bump to 3.5.1

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 119 insertions, 0 deletions

diff --git a/media-sound/musescore/Manifest b/media-sound/musescore/Manifest
index ab4d5cc6f7ec..65fc474cb64f 100644
--- a/media-sound/musescore/Manifest
+++ b/media-sound/musescore/Manifest
@@ -1,2 +1,3 @@
 DIST MuseScore_General-0.2.0.tar.bz2 35122747 BLAKE2B 7f9cafb7912ab8c977842c51df69506d4ad3d1d37498c856978a2d5ab50a1c4fe9145a4807f8c353e6f14138704abb2bbd70c948f1621b494c6e0458c2df0184 SHA512 69eeb22e8c9d1d393a2af857baeb8e49bf2a492651d18190685c74df84a5f6b424e37077e39d9d69c117c4896ea1fbb857eba25a1fbcb6f98d53f384a55713cc
+DIST musescore-3.5.1.tar.gz 66952759 BLAKE2B 74907cc3a7c2305f26a763c12d5bba63a42d720bf97103c366e8d51ca513f8e77e3e950c6674c1c68f71b6e73deaf75dc35de82ee509df632ba3752a34486122 SHA512 ae3907f0cc39f0855fe5069a21d87c5c6ddc31811def36ebf9e069be773693363569fb6b7ad35ff9bf2a64c771133b7c68d50636af9e0733743dd365bc86f654
 DIST musescore-3.5.tar.gz 66798006 BLAKE2B dc3a30d187d22124216023597e98b80d13bc7a47181b65978b2a3c91c419e2783d6fa499b6bed6dcb122155a0b6f72a3ec89d0c9be4355e7afe10bc4fca1a907 SHA512 db2d22abf1b53e37ea5e3b2f367dc945afa3bab7fb4c5b3b5c172498060170a3b0a96767584c0959b29c412729eb059917b98058c6b11e30f54ec4047a775e96
diff --git a/media-sound/musescore/musescore-3.5.1.ebuild b/media-sound/musescore/musescore-3.5.1.ebuild
new file mode 100644
index 000000000000..59c8b43c79bd
--- /dev/null
+++ b/media-sound/musescore/musescore-3.5.1.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+CHECKREQS_DISK_BUILD=3500M
+inherit cmake xdg check-reqs
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/MuseScore.git"
+else
+	SRC_URI="https://github.com/musescore/MuseScore/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+	S="${WORKDIR}/MuseScore-${PV}"
+fi
+
+DESCRIPTION="WYSIWYG Music Score Typesetter"
+HOMEPAGE="https://musescore.org/"
+# MuseScore_General-*.tar.bz2 packaged from https://ftp.osuosl.org/pub/musescore/soundfont/MuseScore_General/
+# It has to be repackaged because the files are not versioned, current version can be found in VERSION file there.
+SRC_URI+=" https://dev.gentoo.org/~fordfrog/distfiles/MuseScore_General-0.2.0.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="alsa debug jack mp3 osc omr portaudio portmidi pulseaudio +sf3 sfz webengine"
+REQUIRED_USE="portmidi? ( portaudio )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-qt/designer:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qthelp:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtquickcontrols2:5
+	>=dev-qt/qtsingleapplication-2.6.1_p20171024[X]
+	dev-qt/qtsvg:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	>=media-libs/freetype-2.5.2
+	media-libs/libsndfile
+	sys-libs/zlib:=
+	alsa? ( >=media-libs/alsa-lib-1.0.0 )
+	jack? ( virtual/jack )
+	mp3? ( media-sound/lame )
+	omr? ( app-text/poppler )
+	portaudio? ( media-libs/portaudio )
+	portmidi? ( media-libs/portmidi )
+	pulseaudio? ( media-sound/pulseaudio )
+	sf3? ( media-libs/libvorbis )
+	webengine? ( dev-qt/qtwebengine:5[widgets] )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.0.1-man-pages.patch"
+	"${FILESDIR}/${PN}-3.5-lambda-capture-this.patch"
+	"${FILESDIR}/${PN}-3.5-remove-duplicite-declaration.patch"
+)
+
+src_unpack() {
+	if [[ ${PV} == "9999" ]]; then
+		git-r3_src_unpack
+		unpack ${A}
+	else
+		default
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Move soundfonts to the correct directory
+	mv "${WORKDIR}"/sound/* "${S}"/share/sound/ || die "Failed to move soundfont files"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DAEOLUS=OFF # does not compile
+		-DBUILD_ALSA="$(usex alsa)"
+		-DBUILD_CRASH_REPORTER=OFF
+		-DBUILD_JACK="$(usex jack)"
+		-DBUILD_LAME="$(usex mp3)"
+		-DBUILD_PCH=ON
+		-DBUILD_PORTAUDIO="$(usex portaudio)"
+		-DBUILD_PORTMIDI="$(usex portmidi)"
+		-DBUILD_PULSEAUDIO="$(usex pulseaudio)"
+		-DBUILD_SHARED_LIBS=ON
+		-DBUILD_TELEMETRY_MODULE=ON
+		-DBUILD_WEBENGINE="$(usex webengine)"
+		-DCMAKE_SKIP_RPATH=ON
+		-DDOWNLOAD_SOUNDFONT=OFF
+		-DHAS_AUDIOFILE=ON
+		-DOCR=OFF
+		-DOMR="$(usex omr)"
+		-DSOUNDFONT3=ON
+		-DZERBERUS="$(usex sfz)"
+		-DUSE_PATH_WITH_EXPLICIT_QT_VERSION=ON
+		-DUSE_SYSTEM_FREETYPE=ON
+		-DUSE_SYSTEM_POPPLER=ON
+		-DUSE_SYSTEM_QTSINGLEAPPLICATION=ON
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cd "${BUILD_DIR}" || die
+	cmake_build -j1 lrelease manpages
+	cmake_src_compile
+}