media-sound/jack2: bump to 1.9.16 + py3.9 + sync'd live

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 108 insertions, 7 deletions

diff --git a/media-sound/jack2/Manifest b/media-sound/jack2/Manifest
index fca4188fb5b8..164a6c80b7bb 100644
--- a/media-sound/jack2/Manifest
+++ b/media-sound/jack2/Manifest
@@ -1 +1,2 @@
 DIST jack2-1.9.14.tar.gz 6495043 BLAKE2B 9ace1cef2c15c2894831c79bb8d73637df27a21462f654e04b7fb8fc05731e6df898aaefc343a9be4799bcd70576aa7397f2d48b7d2530b682f62463ce3d4a07 SHA512 ca9738fd5aadcb7e125f98a358437905959afebe0b792cab316fc31410e89ea3aefdb85154792a9d0a80fa988aa7eff379ff5c7ac6c4bfa1d57ad3d7de7b5fdd
+DIST jack2-1.9.16.tar.gz 974652 BLAKE2B ff20d57f544bd636d93e77c2c6dec3af3afbafe4a217ba480c66247ddb6d8ca60755fa55599240fdd75e8ce2c1f7d8fb4f1bf68de8a212268588245f35731ead SHA512 8e4717cad097806a436e3a7b7977faa65987ca0fe59fd285014d6207899c62f9abbb79474170d0e5a6e82d0dbfe998c1310b13c4de8cd68cea0a6935ba579fd1
diff --git a/media-sound/jack2/jack2-1.9.16.ebuild b/media-sound/jack2/jack2-1.9.16.ebuild
new file mode 100644
index 000000000000..d0bf48e41848
--- /dev/null
+++ b/media-sound/jack2/jack2-1.9.16.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+PYTHON_REQ_USE="threads(+)"
+inherit python-single-r1 waf-utils multilib-minimal
+
+DESCRIPTION="Jackdmp jack implemention for multi-processor machine"
+HOMEPAGE="https://jackaudio.org/"
+
+if [[ "${PV}" = "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/jackaudio/${PN}.git"
+else
+	MY_PV="${PV/_rc/-RC}"
+	MY_P="${PN}-${MY_PV}"
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://github.com/jackaudio/jack2/archive/v${MY_PV}/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="2"
+IUSE="alsa +classic dbus doc ieee1394 libsamplerate metadata opus pam readline sndfile"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	|| ( classic dbus )"
+
+CDEPEND="${PYTHON_DEPS}
+	media-libs/libsamplerate
+	media-libs/libsndfile
+	sys-libs/readline:0=
+	alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
+	dbus? (
+		dev-libs/expat[${MULTILIB_USEDEP}]
+		sys-apps/dbus[${MULTILIB_USEDEP}]
+	)
+	ieee1394? ( media-libs/libffado:=[${MULTILIB_USEDEP}] )
+	metadata? ( sys-libs/db:* )
+	opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+RDEPEND="${CDEPEND}
+	dbus? (
+		$(python_gen_cond_dep '
+			dev-python/dbus-python[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+	pam? ( sys-auth/realtime-base )
+	!media-sound/jack-audio-connection-kit:0"
+
+DOCS=( AUTHORS.rst ChangeLog.rst README.rst README_NETJACK2 )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.9.14-fix-doc.patch"
+)
+
+src_prepare() {
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local mywafconfargs=(
+		--htmldir=/usr/share/doc/${PF}/html
+		$(usex dbus --dbus "")
+		$(usex classic --classic "")
+		--alsa=$(usex alsa yes no)
+		--celt=no
+		--db=$(usex metadata yes no)
+		--doxygen=$(multilib_native_usex doc yes no)
+		--firewire=$(usex ieee1394 yes no)
+		--iio=no
+		--opus=$(usex opus yes no)
+		--portaudio=no
+		--readline=$(multilib_native_usex readline yes no)
+		--samplerate=$(multilib_native_usex libsamplerate yes no)
+		--sndfile=$(multilib_native_usex sndfile yes no)
+		--winmme=no
+	)
+
+	waf-utils_src_configure ${mywafconfargs[@]}
+}
+
+multilib_src_compile() {
+	WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_compile
+}
+
+multilib_src_install() {
+	WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_install
+}
+
+multilib_src_install_all() {
+	python_fix_shebang "${ED}"
+}
diff --git a/media-sound/jack2/jack2-9999.ebuild b/media-sound/jack2/jack2-9999.ebuild
index a05c1b121090..d76f72a16250 100644
--- a/media-sound/jack2/jack2-9999.ebuild
+++ b/media-sound/jack2/jack2-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=6
 
-PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_COMPAT=( python3_{6,7,8,9} )
 PYTHON_REQ_USE="threads(+)"
 inherit python-single-r1 waf-utils multilib-minimal
 
@@ -17,18 +17,19 @@ else
 	MY_PV="${PV/_rc/-RC}"
 	MY_P="${PN}-${MY_PV}"
 	S="${WORKDIR}/${MY_P}"
-	SRC_URI="SRC_URI="https://github.com/jackaudio/jack2/releases/download/v${MY_PV}/v${MY_PV}.tar.gz -> ${P}.tar.gz""
-	KEYWORDS="~amd64 ~ppc ~x86"
+	SRC_URI="https://github.com/jackaudio/jack2/archive/v${MY_PV}/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
 fi
 
 LICENSE="GPL-2"
 SLOT="2"
 IUSE="alsa +classic dbus doc ieee1394 libsamplerate metadata opus pam readline sndfile"
 
-REQUIRED_USE="${PYTHON_REQUIRED_USE}
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
 	|| ( classic dbus )"
 
-COMMON_DEPEND="${PYTHON_DEPS}
+CDEPEND="${PYTHON_DEPS}
 	media-libs/libsamplerate
 	media-libs/libsndfile
 	sys-libs/readline:0=
@@ -40,10 +41,10 @@ COMMON_DEPEND="${PYTHON_DEPS}
 	ieee1394? ( media-libs/libffado:=[${MULTILIB_USEDEP}] )
 	metadata? ( sys-libs/db:* )
 	opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )"
-DEPEND="${COMMON_DEPEND}
+DEPEND="${CDEPEND}
 	virtual/pkgconfig
 	doc? ( app-doc/doxygen )"
-RDEPEND="${COMMON_DEPEND}
+RDEPEND="${CDEPEND}
 	dbus? (
 		$(python_gen_cond_dep '
 			dev-python/dbus-python[${PYTHON_MULTI_USEDEP}]