media-libs/shaderc: add 2022.2

Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

2 files changed, 89 insertions, 0 deletions

diff --git a/media-libs/shaderc/Manifest b/media-libs/shaderc/Manifest
index 83836c899286..bc02a39a9b6d 100644
--- a/media-libs/shaderc/Manifest
+++ b/media-libs/shaderc/Manifest
@@ -1 +1,2 @@
 DIST shaderc-2022.1.tar.gz 222009 BLAKE2B c6707699a49c130b2669620e11f52862790999954a84b05f9f54d238fb0ae68e2523cc4b86104b3d4bce4528db31be89e441b278a97a375b90d7e0f458075f51 SHA512 21c2462cb434d94da87c71ba660f6cd5b161450d7faeff8789b41db25e64f2baa7c560e78aa856d128c5a73699215d6b1085b5ca19a4640237adf194793ad44b
+DIST shaderc-2022.2.tar.gz 223386 BLAKE2B feb18bef51bea72574d784d4992e5b8514b0d1d70fbd9194ad842a361740ed3d66c6c3d2cf6114a0ef77279845ab686d01ad5fcd91cbddcc289cee4e521aec6a SHA512 85962f17d07496ba4cef3ad62dc7fd1967ff628449ceb1fec77336211fddbd2554ea94e5558cfaf2cfe4dcfdf6f56744d905714be7dbb776ba2bcd67e4665039
diff --git a/media-libs/shaderc/shaderc-2022.2.ebuild b/media-libs/shaderc/shaderc-2022.2.ebuild
new file mode 100644
index 000000000000..792146ea3a6c
--- /dev/null
+++ b/media-libs/shaderc/shaderc-2022.2.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake-multilib python-any-r1
+
+DESCRIPTION="Collection of tools, libraries and tests for shader compilation"
+HOMEPAGE="https://github.com/google/shaderc"
+EGIT_COMMIT="${PV}"
+SRC_URI="https://github.com/google/${PN}/archive/v${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-util/glslang-1.3.224[${MULTILIB_USEDEP}]
+	>=dev-util/spirv-tools-1.3.224[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	>=dev-util/spirv-headers-1.3.224
+	test? (	dev-cpp/gtest	)
+"
+BDEPEND="doc? ( dev-ruby/asciidoctor )
+	test? (	$(python_gen_any_dep 'dev-python/nose[${PYTHON_USEDEP}]') )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2020.4-fix-build.patch
+)
+
+# https://github.com/google/shaderc/issues/470
+RESTRICT=test
+
+python_check_deps() {
+	if use test; then
+		python_has_version "dev-python/nose[${PYTHON_USEDEP}]"
+	fi
+}
+
+src_prepare() {
+	cmake_comment_add_subdirectory examples
+
+	# Unbundle glslang, spirv-headers, spirv-tools
+	cmake_comment_add_subdirectory third_party
+	sed -i \
+		-e "s|\$<TARGET_FILE:spirv-dis>|${EPREFIX}/usr/bin/spirv-dis|" \
+		glslc/test/CMakeLists.txt || die
+
+	# Disable git versioning
+	sed -i -e '/build-version/d' glslc/CMakeLists.txt || die
+
+	# Manually create build-version.inc as we disabled git versioning
+	cat <<- EOF > glslc/src/build-version.inc || die
+		"${P}\n"
+		"$(best_version dev-util/spirv-tools)\n"
+		"$(best_version dev-util/glslang)\n"
+	EOF
+
+	cmake_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DSHADERC_SKIP_TESTS="$(usex !test)"
+		-DSHADERC_ENABLE_WERROR_COMPILE="false"
+	)
+	cmake_src_configure
+}
+
+multilib_src_compile() {
+	if multilib_is_native_abi && use doc; then
+		cmake_src_compile glslc_doc_README
+	fi
+	cmake_src_compile
+}
+
+multilib_src_install() {
+	if multilib_is_native_abi; then
+		use doc && local HTML_DOCS=( "${BUILD_DIR}/glslc/README.html" )
+	fi
+	cmake_src_install
+}