media-libs/libde265: bump to 1.0.11, sync live

Bug: https://bugs.gentoo.org/889876
Signed-off-by: John Helmert III <ajak@gentoo.org>

3 files changed, 99 insertions, 4 deletions

diff --git a/media-libs/libde265/Manifest b/media-libs/libde265/Manifest
index 6d20c97ef4c1..32075533abd1 100644
--- a/media-libs/libde265/Manifest
+++ b/media-libs/libde265/Manifest
@@ -1,2 +1,3 @@
+DIST libde265-1.0.11.tar.gz 845996 BLAKE2B 91711132757a10f0f277800525ee6f6a3902604cc969b8756232b15b581d830951d70bccd57d7731b3ad670a3b7a0d2c22e9578f3763da65b3cdeb016422568b SHA512 2ce28558c66e20714c07bf3011bc10dccabb770649903616bc32f1c4f18beba559ef7e0e42365ead77d7e813316b8c051039dc393cd351221cbab7248b3fa34c
 DIST libde265-1.0.8.tar.gz 381963 BLAKE2B 0577623de2ef86e1122b5b5c3642a750bb222c4988a996168e060e8ffd9f5c0787d31331cc8738362d3fc3fb31e8eb659629cab068f0ff1c71de9d15ed1f2ceb SHA512 0007138cb5da0d4cad1e118c01de249580f39c387a11f490d1e1f63ad0968ee2f7951e54580f298b3dbe31e5a3d1a7fa04454e11cbb82beaf8a9aaf56f5532ed
 DIST libde265-1.0.9.tar.gz 845520 BLAKE2B 155a0ac1e14c568c0fb559beb89f3bbde67239ae2ac13dda5ad30d36b59a79d68f399c8d8192ad5190cb8286b03ab03714a9cf89ac139264773c4ff368a97b7e SHA512 225f9aa25eb6565ebf4f549d9d427ae278c4f6f67c76c51bcad79188faac0f5c93e9538357b264a7e2e9043014ccbc07750fb7d1ce1e7bb87fe2e0d1782cba61
diff --git a/media-libs/libde265/libde265-1.0.11.ebuild b/media-libs/libde265/libde265-1.0.11.ebuild
new file mode 100644
index 000000000000..ca34a4a3dccb
--- /dev/null
+++ b/media-libs/libde265/libde265-1.0.11.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/strukturag/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/strukturag/libde265/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Open h.265 video codec implementation"
+HOMEPAGE="https://github.com/strukturag/libde265"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="enc265 dec265 sdl tools debug cpu_flags_x86_sse4_1 cpu_flags_arm_neon cpu_flags_arm_thumb"
+# IUSE+=" sherlock265" # Require libvideogfx or libswscale
+
+RDEPEND="
+	dec265? (
+		sdl? ( media-libs/libsdl )
+	)"
+
+# Sherlock265 require libvideogfx or libswscale
+#RDEPEND+="
+#	sherlock265? (
+#		media-libs/libsdl
+#		dev-qt/qtcore:5
+#		dev-qt/qtgui:5
+#		dev-qt/qtwidgets:5
+#		media-libs/libswscale
+#	)
+#"
+
+DEPEND="${RDEPEND}"
+BDEPEND="dec265? ( virtual/pkgconfig )"
+
+# Sherlock265 require libvideogfx or libswscale
+#BDEPEND+=" sherlock265? ( virtual/pkgconfig )"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.0.2-qtbindir.patch )
+
+src_prepare() {
+	default
+
+	eautoreconf
+
+	# without this, headers would be missing and make would fail
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-log-error
+		ax_cv_check_cflags___msse4_1=$(usex cpu_flags_x86_sse4_1)
+		ax_cv_check_cflags___mfpu_neon=$(usex cpu_flags_arm_neon)
+		$(use_enable cpu_flags_arm_thumb thumb)
+		$(use_enable debug log-info)
+		$(use_enable debug log-debug)
+		$(use_enable debug log-trace)
+		$(multilib_native_use_enable enc265 encoder)
+		$(multilib_native_use_enable dec265)
+	)
+
+	# myeconfargs+=( $(multilib_native_use_enable sherlock265) ) # Require libvideogfx or libswscale
+	myeconfargs+=( --disable-sherlock265 )
+
+	econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+	default
+
+	if multilib_is_native_abi; then
+		# Remove useless, unready and test tools
+		rm "${ED}"/usr/bin/{tests,gen-enc-table,yuv-distortion} || die
+		if ! use tools; then
+			rm "${ED}"/usr/bin/{bjoentegaard,block-rate-estim,rd-curves} || die
+			rm "${ED}"/usr/bin/acceleration_speed || die
+		fi
+	else
+		# Remove all non-native binary tools
+		rm "${ED}"/usr/bin/* || die
+	fi
+}
+
+multilib_src_install_all() {
+	find "${ED}" -name '*.la' -delete || die
+	einstalldocs
+}
diff --git a/media-libs/libde265/libde265-9999.ebuild b/media-libs/libde265/libde265-9999.ebuild
index 4146cf2ae597..ca34a4a3dccb 100644
--- a/media-libs/libde265/libde265-9999.ebuild
+++ b/media-libs/libde265/libde265-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 inherit autotools multilib-minimal
 
@@ -9,7 +9,7 @@ if [[ ${PV} == *9999 ]] ; then
 	EGIT_REPO_URI="https://github.com/strukturag/${PN}.git"
 	inherit git-r3
 else
-	SRC_URI="https://github.com/strukturag/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	SRC_URI="https://github.com/strukturag/libde265/releases/download/v${PV}/${P}.tar.gz"
 	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
 fi
 
@@ -56,7 +56,6 @@ src_prepare() {
 
 multilib_src_configure() {
 	local myeconfargs=(
-		--disable-static
 		--enable-log-error
 		ax_cv_check_cflags___msse4_1=$(usex cpu_flags_x86_sse4_1)
 		ax_cv_check_cflags___mfpu_neon=$(usex cpu_flags_arm_neon)