media-gfx/tuxpaint: version bump to 0.9.24

Closes: https://bugs.gentoo.org/385951
Closes: https://bugs.gentoo.org/581036
Closes: https://bugs.gentoo.org/671528
Closes: https://bugs.gentoo.org/734048
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Peter Alfredsen <crabbedhaloablution@icloud.com>
Closes: https://github.com/gentoo/gentoo/pull/18669
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 72 insertions, 0 deletions

diff --git a/media-gfx/tuxpaint/Manifest b/media-gfx/tuxpaint/Manifest
index d655340a80e8..97bc4b03c544 100644
--- a/media-gfx/tuxpaint/Manifest
+++ b/media-gfx/tuxpaint/Manifest
@@ -1 +1,2 @@
 DIST tuxpaint-0.9.21.tar.gz 9543034 BLAKE2B 196a743542d72e3dc5cea69b9e66a3baecdde7e3b288cb6759632d2b472f69db8d70ad404737416afe7f2ef4d0c0d21c7b2caadb64ca8d21a909e275ee6fcc46 SHA512 fafd80fe7a5a4d65236c8b5a4f15c644c76180e0e4ed7e774795572b70cc38ddb3273be2a93f041d74a1e536a5a9386c18e51987425ea1a3ff910661e4b0afb3
+DIST tuxpaint-0.9.24.tar.gz 15561675 BLAKE2B 971baec8b7728cbb54a2a45b604c152a9620d0f6a1856cca99482ad0fd76f2a4493aab81f54e10e5da4d81800b0e3506cb73dda0e00510ef966b0c98f8aa5cb4 SHA512 a4ee9eea833f9a6313701a4686f9f276570df84436c68d9a3d04e9448a8ea00833207e1034965e15145be744194c7b9a7d3c91bdfa3489d06a61de84b64cc723
diff --git a/media-gfx/tuxpaint/tuxpaint-0.9.24.ebuild b/media-gfx/tuxpaint/tuxpaint-0.9.24.ebuild
new file mode 100644
index 000000000000..21f61535665c
--- /dev/null
+++ b/media-gfx/tuxpaint/tuxpaint-0.9.24.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs xdg
+
+DESCRIPTION="Drawing program designed for young children"
+HOMEPAGE="http://www.tuxpaint.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+RDEPEND="
+	app-text/libpaper
+	dev-libs/fribidi
+	gnome-base/librsvg:2
+	>=media-libs/libpng-1.2:0=
+	>=media-libs/freetype-2:2
+	media-libs/libsdl
+	media-libs/sdl-image[png]
+	media-libs/sdl-mixer
+	media-libs/sdl-pango
+	media-libs/sdl-ttf
+	x11-libs/cairo
+	"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/gperf
+	media-gfx/imagemagick[png]
+	sys-devel/gettext
+	"
+
+src_prepare() {
+	xdg_src_prepare
+	sed -i \
+		-e 's|linux_ARCH_INSTALL:=install-xdg|linux_ARCH_INSTALL:=|' \
+		-e "s|linux_PREFIX:=/usr/local|linux_PREFIX:=/usr|" \
+		-e "s:/lib/:/$(get_libdir)/:g" \
+		-e 's:/share/doc/tuxpaint-$(VER_VERSION)/:'"/share/doc/${PF}/:g" \
+		-e '/@gzip -f/d' \
+		-e '/@chmod a+rx,g-w,o-w $(MAN_PREFIX)/d' \
+		-e "s|linux_ARCH_CFLAGS:=|linux_ARCH_CFLAGS:= ${CFLAGS}|" \
+		Makefile || die
+}
+
+src_compile() {
+	# parallel build may break things
+	emake -j1 CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install
+	local file size
+	for file in data/images/icon[0-9]*x[0-9]*.png; do
+		size=${file##*/icon}
+		size=${size%%x*}
+		newicon -s "${size}" "${file}" tux4kids-tuxpaint.png
+	done
+	newmenu src/tuxpaint.desktop tux4kids-tuxpaint.desktop
+	dodoc docs/*.txt
+	dodoc docs/en/*.txt
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	if ! has_version "media-gfx/tuxpaint-stamps"; then
+		elog "For additional graphic stamps, you can emerge the"
+		elog "media-gfx/tuxpaint-stamps package."
+	fi
+}