kde-plasma/plasma-nm: 5.20.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/kde-plasma/plasma-nm/Manifest b/kde-plasma/plasma-nm/Manifest
index a5e1726fed4c..5a87ef97a260 100644
--- a/kde-plasma/plasma-nm/Manifest
+++ b/kde-plasma/plasma-nm/Manifest
@@ -1 +1,2 @@
 DIST plasma-nm-5.19.5.tar.xz 855504 BLAKE2B a2437794d9de5a0fda6328dd0e352fad956710cef06f9bc2d6590dbde7f2eb469d051db6fc4ce647fe59bf95e48e6e6c9ff68e512a2992abe183ab309112f94d SHA512 2fdd42e7c9bba0b069e0ca39f8ef996b36a807a4065172a816023c32d5d24869bf92c577c9cc5a08bb9e8b13c628b7cbd8346d17dc1e6814c931f7f7ec9439a7
+DIST plasma-nm-5.20.0.tar.xz 842416 BLAKE2B 51e553fd14662327339a909edbc9f6339bf2e6b8eb7a5da619f7580ce154e7ffdc49d9eddbd5d9e537d92f4bc72b24b813b1ace74b1ea058e8238ef8db5b67c9 SHA512 db78e2c65a09cf6d77032c1a63ba0d66bac3946944a25f08f7267bfb776a39736189668ab3e2eaa815f09f0d7993bdc1384f9267e035053e40051b23a204d7f5
diff --git a/kde-plasma/plasma-nm/plasma-nm-5.20.0.ebuild b/kde-plasma/plasma-nm/plasma-nm-5.20.0.ebuild
new file mode 100644
index 000000000000..dec9064ff778
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-5.20.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+KFMIN=5.74.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.1
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="modemmanager openconnect teamd"
+
+DEPEND="
+	>=app-crypt/qca-2.3.0:2
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	net-misc/networkmanager[teamd=]
+	modemmanager? (
+		>=dev-qt/qtxml-${QTMIN}:5
+		>=kde-frameworks/modemmanager-qt-${KFMIN}:5
+		net-misc/mobile-broadband-provider-info
+	)
+	openconnect? (
+		>=dev-qt/qtxml-${QTMIN}:5
+		net-vpn/networkmanager-openconnect
+		net-vpn/openconnect:=
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_MODEMMANAGER_SUPPORT=$(usex !modemmanager)
+		$(cmake_use_find_package modemmanager KF5ModemManagerQt)
+		$(cmake_use_find_package openconnect OpenConnect)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version "kde-plasma/plasma-workspace:5"; then
+		elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
+		elog "However, the networkmanagement KCM can be called from either systemsettings"
+		elog "or manually: $ kcmshell5 kcm_networkmanagement"
+	fi
+}