kde-apps/gwenview: 21.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 109 insertions, 0 deletions

diff --git a/kde-apps/gwenview/Manifest b/kde-apps/gwenview/Manifest
index 9daa98e8219f..912bc0bf8e80 100644
--- a/kde-apps/gwenview/Manifest
+++ b/kde-apps/gwenview/Manifest
@@ -1 +1,2 @@
 DIST gwenview-20.12.3.tar.xz 6753636 BLAKE2B ebf4cb69941875f9f2cda8816ff16953fd82a8a434efb18dab60c4ce53e1cd4e76ae8d51ef619b39f18fde82a2fb0943b2a24465513fe85cdb774d411e389c38 SHA512 4a2973029d7bb2e8883cebb8b031fa60068b3a258eceb165a8ba2dcfe52d63fa3c505772a895d72aae93bf88b024fbbb2189e9f1b982ecd94a3629f67d15eb2b
+DIST gwenview-21.04.0.tar.xz 6757484 BLAKE2B ccc9b044d29a9b91bd6c16fac1e25c815a8334747b037a7110bcb3b1c227502490f22f6e03a1195eceb370e15a675bcb15c8a4d1c79b23566ec26bb8547f0a16 SHA512 68a890a11d8cb7c63f414ad940eead983a59886c9a24e7b06376f7edd388f020d337768ca78c1adf654b22aa358c65c5886b52c7fde315d6af7cd7fba2ceda3f
diff --git a/kde-apps/gwenview/gwenview-21.04.0.ebuild b/kde-apps/gwenview/gwenview-21.04.0.ebuild
new file mode 100644
index 000000000000..929ef2ecd4ae
--- /dev/null
+++ b/kde-apps/gwenview/gwenview-21.04.0.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.80.0
+QTMIN=5.15.2
+inherit ecm kde.org optfeature
+
+DESCRIPTION="Image viewer by KDE"
+HOMEPAGE="https://apps.kde.org/en/gwenview https://userbase.kde.org/Gwenview"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="activities fits kipi +mpris raw semantic-desktop share X"
+
+# requires running environment
+RESTRICT+=" test"
+
+COMMON_DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	media-gfx/exiv2:=
+	media-libs/lcms:2
+	media-libs/libpng:0=
+	>=media-libs/phonon-4.11.0
+	media-libs/tiff
+	virtual/jpeg:0
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+	fits? ( sci-libs/cfitsio )
+	kipi? ( >=kde-apps/libkipi-${PVCUT}:5= )
+	mpris? ( >=dev-qt/qtdbus-${QTMIN}:5 )
+	raw? ( >=kde-apps/libkdcraw-${PVCUT}:5 )
+	semantic-desktop? (
+		>=kde-frameworks/baloo-${KFMIN}:5
+		>=kde-frameworks/kfilemetadata-${KFMIN}:5
+	)
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtimageformats-${QTMIN}:5
+	>=kde-frameworks/kimageformats-${KFMIN}:5
+	kipi? ( >=kde-apps/kipi-plugins-${PVCUT}:5 )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use mpris; then
+		# FIXME: upstream a better solution
+		sed -e "/set(HAVE_QTDBUS/s/\${Qt5DBus_FOUND}/0/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package activities KF5Activities)
+		$(cmake_use_find_package fits CFitsio)
+		$(cmake_use_find_package kipi KF5Kipi)
+		$(cmake_use_find_package raw KF5KDcraw)
+		$(cmake_use_find_package share KF5Purpose)
+		$(cmake_use_find_package X X11)
+	)
+
+	if use semantic-desktop; then
+		mycmakeargs+=( -DGWENVIEW_SEMANTICINFO_BACKEND=Baloo )
+	else
+		mycmakeargs+=( -DGWENVIEW_SEMANTICINFO_BACKEND=None )
+	fi
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "SVG support" kde-apps/svgpart:${SLOT}
+	fi
+	ecm_pkg_postinst
+}