kde-apps: Add KDE Release Service 19.12.0

Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 85 insertions, 0 deletions

diff --git a/kde-apps/ark/Manifest b/kde-apps/ark/Manifest
index bb0d2d3f7d15..bb7485e2c8f6 100644
--- a/kde-apps/ark/Manifest
+++ b/kde-apps/ark/Manifest
@@ -1 +1,2 @@
 DIST ark-19.08.3.tar.xz 2585196 BLAKE2B 2f3ad8052ad5ead34d30d5fff41c076e387740ac77c80791a8f600d9158c254592916a92e8e181b98adee916baee2f58c3d668bfdd1d9d1be7a36f7b8d61c07c SHA512 2bbbce37e5f892840517688eb4ce78770514eb5c780d34ae3c33c4b4e60cd153ebc190e4613411d5e01f01a78b6a74bad86c79b9efe8a156250c18033a3271cf
+DIST ark-19.12.0.tar.xz 2588820 BLAKE2B 6b01d392eec688ecce957d6407bdde335d16d62e2ec456ef5c3f4e8e00887bf8811de98d637b77ef06796539f13cf34319c225f65824cbd867bc757335260860 SHA512 ac4f0379cc7927bada4416a5569c96ace173ec1b85e46e95682f46e254da094d9cfc6049ba8f49c6dcd6bc0d3ee6e08a00150f9f6088ff2325bd1a1179d7184f
diff --git a/kde-apps/ark/ark-19.12.0.ebuild b/kde-apps/ark/ark-19.12.0.ebuild
new file mode 100644
index 000000000000..1c677a7ea9e3
--- /dev/null
+++ b/kde-apps/ark/ark-19.12.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.63.0
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE Archiving tool"
+HOMEPAGE="https://kde.org/applications/utilities/org.kde.ark
+https://utils.kde.org/projects/ark/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="bzip2 lzma zip"
+
+BDEPEND="
+	sys-devel/gettext
+"
+RDEPEND="
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	app-arch/libarchive:=[bzip2?,lzma?,zlib]
+	sys-libs/zlib
+	zip? ( >=dev-libs/libzip-1.2.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+# bug #560548, last checked with 16.04.1
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package bzip2 BZip2)
+		$(cmake_use_find_package lzma LibLZMA)
+		$(cmake_use_find_package zip LibZip)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		if ! has_version app-arch/rar; then
+			elog "For creating/extracting rar archives, installing app-arch/rar is required."
+			if ! has_version app-arch/unar && ! has_version app-arch/unrar; then
+				elog "Alternatively, for only extracting rar archives, install app-arch/unar (free) or app-arch/unrar (non-free)."
+			fi
+		fi
+
+		has_version app-arch/p7zip || \
+			elog "For handling 7-Zip archives, install app-arch/p7zip."
+
+		has_version app-arch/lrzip || \
+			elog "For handling lrz archives, install app-arch/lrzip."
+	fi
+}