gnome-extra/evolution-ews: Version bump to 3.50.1

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/33428
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/gnome-extra/evolution-ews/Manifest b/gnome-extra/evolution-ews/Manifest
index 87ec511972db..a7d9c03674f6 100644
--- a/gnome-extra/evolution-ews/Manifest
+++ b/gnome-extra/evolution-ews/Manifest
@@ -1,2 +1,3 @@
 DIST evolution-ews-3.48.2.tar.xz 701356 BLAKE2B 8c941302f383870bacf0dd3f02b28be34105ec7f612b027a505b98be0f66099d65671808e26e86ce756fc47116d012aa1c82fff74c5a501d3778dc7aba6b2498 SHA512 deccc3b442718b03809a7c49297a3f5d7c0bd2873fddfd9f90861a102208759cb95db9bfec1b04cff6932678f58aa81467c48fd4b1e32bb49ed43b9d8c9f4f77
 DIST evolution-ews-3.50.0.tar.xz 707208 BLAKE2B b2137c393e3ad6f3fdcd865d7dbba8f2830fbf3f287cb5599a23837ca5b4597714deeff08dc6e69443baf96171976476302bafeccdfb0c941c5b63e9a80f69c3 SHA512 51b90c018a5aea84e2c89785edcf69fe396d10d3fe447bc3ea5207506efa6433fe7af5e35ef6e2f5c3c2b8e3218ddff12c5be000dcad50c998c914994ce95745
+DIST evolution-ews-3.50.1.tar.xz 707220 BLAKE2B 8d5e579e885ebdabcbc3f19b18ba8ecaafdf393c473d3f3ca47c0002841634e2fda5c3d3db6ec132c1589a5bc7869e84b36e6761457f00bd999b2e866151b1af SHA512 f02b1815f8d641a5941f67e7b7507966231301f258602b8772e7ae01490f6ac18f66f60609c94e4ea996bf8544a65d5d895dd56a0eabbf7c20a86ff310537c18
diff --git a/gnome-extra/evolution-ews/evolution-ews-3.50.1.ebuild b/gnome-extra/evolution-ews/evolution-ews-3.50.1.ebuild
new file mode 100644
index 000000000000..def2f07990d7
--- /dev/null
+++ b/gnome-extra/evolution-ews/evolution-ews-3.50.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake gnome2 optfeature
+
+DESCRIPTION="Evolution module for connecting to Microsoft Exchange Web Services"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution https://gitlab.gnome.org/GNOME/evolution-ews"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="test"
+
+# libical-glib currently (2020-02-29) oddly behind USE=introspection
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.68:2
+	>=dev-libs/libical-3.0.5:0=[introspection(-)]
+	>=dev-libs/json-glib-1.0.4
+	>=dev-libs/libmspack-0.4
+	dev-libs/libxml2:2
+	>=gnome-extra/evolution-data-server-${PV}:0=
+	>=mail-client/evolution-${PV}:2.0
+	>=net-libs/libsoup-3.0:3.0
+	>=x11-libs/gtk+-3.10:3
+"
+DEPEND="${RDEPEND}
+	test? ( >=net-libs/uhttpmock-0.9:1.0 )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Unittests fail to find libevolution-ews.so
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake_src_prepare call, if that works
+src_prepare() {
+	cmake_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MSPACK=ON
+		-DENABLE_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+}
+
+pkg_postinst() {
+	optfeature "oauth support" "gnome-extra/evolution-data-server[oauth-gtk3]"
+}