gnome-extra/gnome-contacts: Version bump to 44_rc

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/30119
Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 79 insertions, 0 deletions

diff --git a/gnome-extra/gnome-contacts/Manifest b/gnome-extra/gnome-contacts/Manifest
index e815defef632..c8e946d9afa3 100644
--- a/gnome-extra/gnome-contacts/Manifest
+++ b/gnome-extra/gnome-contacts/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-contacts-43.0.tar.xz 380348 BLAKE2B be226024dd8369a3c3df9766d6860912fee5a698ee4e0754d773afe16d7f787f3d8a73485c9a31b091514b7de3a835e3f4e37b6c11fc746e1a5f681e07af58fc SHA512 ee2cfc4ad2318f27b0e6597eae501a6e2240b4de8ceb7982c4942a6ff50ce6cd56d06f5d324ac04f82dd8e7086dc82426fb3aab9c194cbfa490b5bab98ba0469
 DIST gnome-contacts-43.1.tar.xz 384560 BLAKE2B 43f3c0e815e358dc4952f9b389028c8b6ad0590ed3db0e31ce08bf2f76dd75ec5a11afb0660344eee79fd42e7aa9bd4199981bb823505e295e40d3d2a17d4e90 SHA512 4a4513937d0ca2ba35584795fd186ae01e2b2dcab6482ecd73bff24cd4f7abf0a84a7e3305b69aef8de611ee737bc2e572d6be60cea3121850a6e3cf15db0755
+DIST gnome-contacts-44.rc.tar.xz 395224 BLAKE2B cb674f25c6b9b658f581f88f7a285675e79c5e436af65de92a2c77580d2ddfe32aa1d1d34de2894de09b59689ff2880c176fb78e1cdce2eabfc2ce109089988a SHA512 0d01974447689291d69a83cf593938507d813a4c1f3d37b76e56e9d6bee57db12e638a1c37059c0ce26e83fb5362c1881c30da14cd2b2252e3653432bf6b62cf
diff --git a/gnome-extra/gnome-contacts/gnome-contacts-44_rc.ebuild b/gnome-extra/gnome-contacts/gnome-contacts-44_rc.ebuild
new file mode 100644
index 000000000000..3a4a7f17c091
--- /dev/null
+++ b/gnome-extra/gnome-contacts/gnome-contacts-44_rc.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="GNOME contact management application"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Contacts"
+SRC_URI="https://download.gnome.org/sources/${PN}/44/${PN}-44.rc.tar.xz"
+S="${WORKDIR}/${PN}-44.rc"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+gnome-online-accounts"
+
+VALA_DEPEND="
+	$(vala_depend)
+	>=dev-libs/gobject-introspection-1.54
+	dev-libs/folks[vala(+)]
+	gnome-online-accounts? ( net-libs/gnome-online-accounts[vala] )
+	gnome-extra/evolution-data-server[gtk,vala]
+	>=dev-libs/libportal-0.6:=[vala]
+"
+RDEPEND="
+	>=dev-libs/folks-0.14.0:=[eds]
+	>=dev-libs/libgee-0.10:0.8=
+	>=dev-libs/glib-2.64:2
+	>=gui-libs/gtk-4.6:4
+	>=gui-libs/libadwaita-1.2:1
+	>=gnome-extra/evolution-data-server-3.42:=[gnome-online-accounts?]
+	>=dev-libs/libportal-0.6:=
+	>=media-gfx/qrencode-4.1.1
+	gnome-online-accounts? ( net-libs/gnome-online-accounts:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	${VALA_DEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dcamera=true # Ignored
+		-Dmanpage=true
+		-Ddocs=false
+		$(meson_use gnome-online-accounts goa)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
diff --git a/gnome-extra/gnome-contacts/metadata.xml b/gnome-extra/gnome-contacts/metadata.xml
index 6c5da1f9230c..3ea012ef8167 100644
--- a/gnome-extra/gnome-contacts/metadata.xml
+++ b/gnome-extra/gnome-contacts/metadata.xml
@@ -5,6 +5,9 @@
     <email>gnome@gentoo.org</email>
     <name>Gentoo GNOME Desktop</name>
   </maintainer>
+   <use>
+    <flag name="gnome-online-accounts">Enable <pkg>net-libs/gnome-online-accounts</pkg> based Google authentication support</flag>
+  </use>
   <upstream>
     <remote-id type="gnome-gitlab">GNOME/gnome-contacts</remote-id>
   </upstream>