dev-util/glade: Version bump to 3.40.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-util/glade/Manifest b/dev-util/glade/Manifest
index 0ba975c1b9d5..cacf89522266 100644
--- a/dev-util/glade/Manifest
+++ b/dev-util/glade/Manifest
@@ -1 +1,2 @@
 DIST glade-3.38.2.tar.xz 2709224 BLAKE2B 2bcd447b90d6e67abc44dd273f0f5d7fc1d6848ef0bd878481f2c10e8846828e63fbf9c9c96e5effe8126b4aec7eb05886606ca1dc5fb94943bc5d1d8d0ef4e2 SHA512 2df8c8363206905663cd3ac9196da44445425a888b64f1b3b3ac6cd41e14c4a82a5d2c299730ef0606c3970a04dd8f245bb5639218794eb67dcbd26fae17565e
+DIST glade-3.40.0.tar.xz 2654772 BLAKE2B 472dfd841e9501f7bbc96bde49ebe26dfd54193cd479658d042547eba5d1af196c0a06212ec5c894c53c12f3791967f6c77859f96802e3df5760b36c6c0c4af1 SHA512 6b018f882e9d155a4b2256c0b4c72743f971c8d730a53f16faa240d01e14051f5b6ce04e355dcc78e1679579fb091facaa06acdda6297c5b8efc642c42bb7b4e
diff --git a/dev-util/glade/glade-3.40.0.ebuild b/dev-util/glade/glade-3.40.0.ebuild
new file mode 100644
index 000000000000..6204835b1876
--- /dev/null
+++ b/dev-util/glade/glade-3.40.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome2 python-single-r1 meson optfeature virtualx
+
+DESCRIPTION="A user interface designer for GTK+ and GNOME"
+HOMEPAGE="https://glade.gnome.org https://gitlab.gnome.org/GNOME/glade"
+
+LICENSE="GPL-2+ FDL-1.1+"
+SLOT="3.10/13" # subslot = suffix of libgladeui-2.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="gjs gtk-doc +introspection python webkit"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	dev-libs/atk[introspection?]
+	>=dev-libs/glib-2.53.2:2
+	>=dev-libs/libxml2-2.4.0:2
+	x11-libs/cairo:=
+	x11-libs/gdk-pixbuf:2[introspection?]
+	>=x11-libs/gtk+-3.22.0:3[introspection?]
+	x11-libs/pango[introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	gjs? ( >=dev-libs/gjs-1.64.0 )
+	python? (
+		${PYTHON_DEPS}
+		x11-libs/gtk+:3[introspection]
+		$(python_gen_cond_dep '
+			>=dev-python/pygobject-3.8:3[${PYTHON_USEDEP}]
+		')
+	)
+	webkit? ( >=net-libs/webkit-gtk-2.12.0:4 )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	app-text/docbook-xml-dtd:4.1.2
+	dev-libs/libxslt
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+RESTRICT="test" # https://gitlab.gnome.org/GNOME/glade/issues/333
+
+PATCHES=(
+	# To avoid file collison with other slots, rename help module.
+	# Prevent the UI from loading glade:3's gladeui devhelp documentation.
+	"${FILESDIR}"/${PN}-3.14.1-doc-version.patch
+)
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgladeui=true
+		$(meson_feature gjs)
+		$(meson_feature python)
+		$(meson_feature webkit webkit2gtk)
+
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	optfeature_header
+	optfeature "integration API documentation support" dev-util/devhelp
+}