dev-tex/rubber: add ebuild for version 1.6.0-alpha1

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Florian Schmaus <flo@geekplace.eu>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 98 insertions, 0 deletions

diff --git a/dev-tex/rubber/Manifest b/dev-tex/rubber/Manifest
index 27a5b7300acb..2ed8104fdd63 100644
--- a/dev-tex/rubber/Manifest
+++ b/dev-tex/rubber/Manifest
@@ -1 +1,2 @@
 DIST rubber-1.5.1.tar.gz 111812 BLAKE2B 4d08527689d669e3ac8dd6e9050fc09766bfb46c53d9923ce10efc0aaf8a62a962cb2f1c27a0e7a19a9be96710edba923d93589d816aa22305eec33fd08aa08c SHA512 ba22eeddc24b4f9abf0bf087604a4261add648877ec558b766555de09538cd20c21c8cfd9731c1421540bb2479501dd6ed066346d250c6bc981529e31efacc40
+DIST rubber-1.6.0-alpha1.tar.bz2 97809 BLAKE2B f2b37c33b6d7ab105b2567ff0b70c5c11333dc76fd633005ae8e1ca36b91e5579a3f75d1c4312b343cffaeff74d65e1046642ea78738b6b1126d3b05b2534ec7 SHA512 7ccc367929c09e01ce8458de5b3e8596cbb549026e7a917a0959733ae63398e903dd3bbcb22493d46073771fb70049207036260104f24693c4a1736e0d534e67
diff --git a/dev-tex/rubber/rubber-1.6.0_alpha1.ebuild b/dev-tex/rubber/rubber-1.6.0_alpha1.ebuild
new file mode 100644
index 000000000000..630795cc124b
--- /dev/null
+++ b/dev-tex/rubber/rubber-1.6.0_alpha1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+DISTUTILS_USE_SETUPTOOLS="no"
+
+inherit distutils-r1
+
+if [[ ${PV} == "9999" ]] || [[ -n "${EGIT_COMMIT_ID}" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/latex-rubber/${PN}.git"
+else
+	UPSTREAM_PV=$(ver_rs 3 -)
+	S="${WORKDIR}/${PN}-${UPSTREAM_PV}"
+	SRC_URI="https://gitlab.com/latex-rubber/${PN}/-/archive/${UPSTREAM_PV}/${PN}-${UPSTREAM_PV}.tar.bz2"
+	KEYWORDS="~amd64 ~ppc ~x86"
+fi
+
+DESCRIPTION="A LaTeX wrapper for automatically building documents"
+HOMEPAGE="https://gitlab.com/latex-rubber/rubber"
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="virtual/latex-base"
+
+# Test dependencies:
+# - app-text/texlive-core for rubber's 'cweave' test
+# - dev-lang/R for rubber's 'knitr' test (requires knitr R library, currently disabled)
+# - dev-texlive/texlive-latexextra for rubber's 'combine' test (currently disabled)
+BDEPEND="
+	${RDEPEND}
+	virtual/texi2dvi
+	test? (
+		app-text/texlive-core
+		dev-texlive/texlive-latexextra
+		media-gfx/asymptote
+		dev-tex/pythontex
+	)
+"
+src_install() {
+	insinto /usr/share/zsh/site-functions
+	newins misc/zsh-completion _rubber
+
+	distutils-r1_src_install
+}
+
+python_install() {
+	local my_install_args=(
+		--mandir="${EPREFIX}/usr/share/man"
+		--infodir="${EPREFIX}/usr/share/info"
+		--docdir="${EPREFIX}/usr/share/doc/${PF}"
+	)
+
+	distutils-r1_python_install "${my_install_args[@]}"
+}
+
+src_test() {
+	cd tests || die
+
+	# Disable the broken 'combine' test as it uses the 'combine' as a
+	# latex package when it is only a document class (probably only in
+	# newer versions of combine). Also note that this tests works
+	# under debian 'buster'. TODO: Look into potential modifications
+	# done by debian.
+	touch combine/disable || die
+
+	# This test does not work under Gentoo nor Debian 'buster'.
+	# TODO: Investigate why it does not work.
+	touch cweb-latex/disable || die
+
+	# TODO: Investigate why the following are failing.
+	touch fig2dev-dvi/disable || die
+	touch fig2dev-path/disable || die
+	touch fig2dev-path-inplace/disable || die
+	touch fig2dev-path-into/disable || die
+	touch graphicx-dotted-files/disable || die
+	touch hooks-input-file/disable || die
+	touch knitr/disable || die
+
+	# Even tough metapost is available, those tests fail on Gentoo
+	# (while they succeed on Debian 'buster').
+	# TODO: Determine why.
+	# ERROR:mpost:I can't read MetaPost's log file, this is wrong.
+	touch metapost/disable || die
+	# expected error message not reported by Rubber
+	touch metapost-error/disable || die
+	# ERROR:mpost:I can't read MetaPost's log file, this is wrong.
+	touch metapost-input/disable || die
+
+	./run.sh * || die
+}