proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-python/xlwt/xlwt-1.0.0.ebuild b/dev-python/xlwt/xlwt-1.0.0.ebuild
new file mode 100644
index 000000000000..37200f7dcc36
--- /dev/null
+++ b/dev-python/xlwt/xlwt-1.0.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library to create spreadsheet files compatible with Excel"
+HOMEPAGE="http://pypi.python.org/pypi/xlwt"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/sphinx-1.3.1[${PYTHON_USEDEP}]
+		dev-python/pkginfo[${PYTHON_USEDEP}]
+	)
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+# Prevent d'loading in the doc build
+PATCHES=( "${FILESDIR}"/docbuild.patch )
+
+python_prepare_all() {
+	# Don't install documentation and examples in site-packages directories.
+	sed -e "/package_data/d" -i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests tests || die "tests failed under ${EPYTHON}}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}