dev-python/uvloop: Bump to 0.15.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 55 insertions, 0 deletions

diff --git a/dev-python/uvloop/Manifest b/dev-python/uvloop/Manifest
index 15625dc68393..00454ce7b1fd 100644
--- a/dev-python/uvloop/Manifest
+++ b/dev-python/uvloop/Manifest
@@ -1 +1,2 @@
 DIST uvloop-0.14.0.tar.gz 2009041 BLAKE2B 4d984f5023e0974ee68795e6cf29585cee32345e8a682611a72dbc36efefdfeeecb3c22aecb581ff7e5ae826345e1de3b0e6c7a6e8319829b0b3cbe5a180ed11 SHA512 8a9a64c91fd34c65a1c40d8d76ad7dbd7e959d45188ef81cdc06995312f52106b2c648a504d51b64b470e54dfc4854dcf9a05cafa3d4a42f1bc1e31766114d61
+DIST uvloop-0.15.0.tar.gz 2086686 BLAKE2B 34bbce58f47a4da1c8fa27011c4a39e864ba1959affe2584eb33425ddb3fbb3a59783e3cf771669cdb1343299bbc7a7a8a14f4bfcbf2b694ac71b9fc055341d1 SHA512 fcb18511a1af89c11cd4022ecb6e8893915a159b34a054bab5e82da3b9127b886ab3e785a98ca39e612cdf2b18abd95bd7fc505808cccf9d4ac281f5a0b6e0d7
diff --git a/dev-python/uvloop/uvloop-0.15.0.ebuild b/dev-python/uvloop/uvloop-0.15.0.ebuild
new file mode 100644
index 000000000000..1ce46b172f5b
--- /dev/null
+++ b/dev-python/uvloop/uvloop-0.15.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+inherit distutils-r1
+
+DESCRIPTION="Ultra-fast implementation of asyncio event loop on top of libuv"
+HOMEPAGE="https://github.com/magicstack/uvloop"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc examples"
+
+RDEPEND=">=dev-libs/libuv-1.11.0:="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		>=dev-python/alabaster-0.6.2[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests setup.py
+
+python_prepare_all() {
+	cat <<EOF >> setup.cfg || die
+[build_ext]
+use-system-libuv=1
+EOF
+
+	# flake8 only
+	rm tests/test_sourcecode.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_ext --inplace build_sphinx
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	use doc && local HTML_DOCS=( "${BUILD_DIR}/sphinx/html/." )
+	distutils-r1_python_install_all
+}