dev-python/notebook: Bump to 6.3.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/dev-python/notebook/Manifest b/dev-python/notebook/Manifest
index 9651db14043f..3cc163ca0354 100644
--- a/dev-python/notebook/Manifest
+++ b/dev-python/notebook/Manifest
@@ -1 +1,2 @@
 DIST notebook-6.2.0.tar.gz 13927515 BLAKE2B ca752f0cb316b46b71d8451c59c196c324008c296dfc7fbc4ee426ba5b3c1035e90170e46720547a9e3f2cf381ab5e0294185ee1a814d31ffbe6ecf546f229d6 SHA512 217392000ca2d0266137f937fc4d2a1b81ed19217fdbf6550b07453eede8b9a6e15c8fbb1c94f559a7f44ac73dfadcefeae815c186e56bb1e9a30120fe070f3a
+DIST notebook-6.3.0.tar.gz 13922153 BLAKE2B f24b03d4887b1e786da215a4ab10d83e4ae8391d1b88559f4bb35fcf7813d98e487447bf21a1772d502d6b3594c53e6e7b743b681cdb07b5118cc4808bcd02a4 SHA512 112bb0b176f7e6584ca0f09d74cb34fe756d0491320dcc23932f84236fd55b9f56f13a7057c89be073486637fc8c0cf2c44dfce18f27fa16ad0f9d15d2bcd5be
diff --git a/dev-python/notebook/notebook-6.3.0.ebuild b/dev-python/notebook/notebook-6.3.0.ebuild
new file mode 100644
index 000000000000..0ee849912ef9
--- /dev/null
+++ b/dev-python/notebook/notebook-6.3.0.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Jupyter Interactive Notebook"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-libs/mathjax-2.4
+	dev-python/argon2-cffi[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	>=www-servers/tornado-6.0[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-4.6.1[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-5.3.4[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.2.0[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-python/prometheus_client[${PYTHON_USEDEP}]"
+
+# sphinx 2+ seems to have a problem with its github plugin. temporarily adding
+# a version constraint.
+BDEPEND="
+	test? (
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}"-5.7.0-no-mathjax.patch
+)
+
+distutils_enable_tests --install pytest
+
+python_prepare_all() {
+	# disable bundled mathjax
+	sed -i 's/^.*MathJax.*$//' bower.json || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local deselect=(
+		# require geckodriver
+		notebook/tests/selenium
+		# trash doesn't seem to work for us
+		notebook/services/contents/tests/test_contents_api.py::GenericFileCheckpointsAPITest::test_checkpoints_follow_file
+		notebook/services/contents/tests/test_contents_api.py::GenericFileCheckpointsAPITest::test_delete
+		notebook/services/contents/tests/test_contents_api.py::GenericFileCheckpointsAPITest::test_delete_dirs
+		notebook/services/contents/tests/test_contents_api.py::GenericFileCheckpointsAPITest::test_delete_non_empty_dir
+		notebook/services/contents/tests/test_manager.py::TestContentsManager::test_delete
+		notebook/services/contents/tests/test_manager.py::TestContentsManagerNoAtomic::test_delete
+		# TODO
+		notebook/services/kernels/tests/test_kernels_api.py::KernelAPITest::test_connections
+		notebook/services/kernels/tests/test_kernels_api.py::AsyncKernelAPITest::test_connections
+		notebook/services/kernels/tests/test_kernels_api.py::KernelCullingTest::test_culling
+	)
+
+	epytest ${deselect[@]/#/--deselect }
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	ln -sf \
+		"${EPREFIX}/usr/share/mathjax" \
+		"${D}$(python_get_sitedir)/notebook/static/components/MathJax" || die
+}
+
+pkg_preinst() {
+	# remove old mathjax folder if present
+	rm -rf "${EROOT}"/usr/lib*/python*/site-packages/notebook/static/components/MathJax || die
+}