dev-python/ipykernel: Bump to 6.21.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index 6f81a67f7a4f..ad0a4d1b9668 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1,2 +1,3 @@
 DIST ipykernel-6.20.2.tar.gz 149263 BLAKE2B 38b3afdbe237ec2facb3af42311315a060f1dba845cb3f7ce10a3d5f68679804640b0dbda869395817a8612af2033f5936ff7f6f3b3b822f47ed512a3b8c0c4d SHA512 9c79c7fa175cd81a920e6b1f2159dda30ba9068437cb1d24b09d864ded36b439045e58f240daee1a46ae375f1990cf318cd8b2e2c02aa6d6e2004d90aff5225a
 DIST ipykernel-6.21.2.tar.gz 150365 BLAKE2B e1bc29018459738a3358af2d4225397028013c1ef9ceb571cb225fafb1a1570c349759caf723e03c6a67a9c354c83d178ae777f7ea4222f5c2ed35e41e22638d SHA512 e4d3aa102d83f9c9b16f392c5b37d55a9cd987ca6a58ce1c4b59d282ec945dcc8803539bf54d7b3bb71c11058fc20a3947fd875bebc5efa5f629015b544fe819
+DIST ipykernel-6.21.3.tar.gz 150659 BLAKE2B 1fd0f0994b0065c662611bf629a4a755a2285b66f9d1e60bcc46fc84a445c7af6b882e09be2c4d26e8ca524a4ccda8534d04e357ec575a8fc034f0f4a437b750 SHA512 68e7bbae60e07805590e00acb186b14ef3c21426db9c49d04b93cb38083a7c5c20b177b72743674224741d8ca946604e8ae733f26d11738b7d99fabdee642064
diff --git a/dev-python/ipykernel/ipykernel-6.21.3.ebuild b/dev-python/ipykernel/ipykernel-6.21.3.ebuild
new file mode 100644
index 000000000000..9967f1a4dbe1
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-6.21.3.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/debugpy-1.6.5[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-8[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-4.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest_asyncio[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-20[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
+
+src_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		ipykernel/tests/test_debugger.py::test_attach_debug
+		ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+		ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
+		ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+		ipykernel/tests/test_debugger.py::test_set_breakpoints
+		ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
+		ipykernel/tests/test_debugger.py::test_copy_to_globals
+		# hangs?
+		ipykernel/tests/test_eventloop.py::test_tk_loop
+	)
+
+	virtx distutils-r1_src_test
+}