dev-python/elasticsearch-curator: bump to 5.5.1

Closes: https://bugs.gentoo.org/653512
Package-Manager: Portage-2.3.31, Repoman-2.3.9

1 files changed, 121 insertions, 0 deletions

diff --git a/dev-python/elasticsearch-curator/elasticsearch-curator-5.5.1.ebuild b/dev-python/elasticsearch-curator/elasticsearch-curator-5.5.1.ebuild
new file mode 100644
index 000000000000..ac00f389bed6
--- /dev/null
+++ b/dev-python/elasticsearch-curator/elasticsearch-curator-5.5.1.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+MY_PN="curator"
+ES_VERSION="6.2.4"
+
+inherit distutils-r1
+
+DESCRIPTION="Tending time-series indices in Elasticsearch"
+HOMEPAGE="https://github.com/elasticsearch/curator"
+SRC_URI="https://github.com/elasticsearch/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	test? ( https://artifacts.elastic.co/downloads/elasticsearch/elasticsearch-${ES_VERSION}.tar.gz )"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="test"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/elasticsearch-py-5.4.0[${PYTHON_USEDEP}]
+	<dev-python/elasticsearch-py-7.0.0[${PYTHON_USEDEP}]
+	>=dev-python/click-6.7[${PYTHON_USEDEP}]
+	>=dev-python/certifi-2018.01.18[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.20[${PYTHON_USEDEP}]
+	>=dev-python/voluptuous-0.9.3[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/sphinx[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND}
+		virtual/jre:1.8
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/nosexcover[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_prepare_all() {
+	# avoid downloading from net
+	sed -e '/^intersphinx_mapping/,+3d' -i docs/conf.py || die
+
+	# allow to use newer dev-python/elasticsearch-py
+	sed -e 's/elasticsearch==5.5.2/elasticsearch>=5.4.0/g' -i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	emake -C docs -j1 man $(usex doc html "")
+}
+
+# tests fail in chroot
+# https://github.com/elastic/elasticsearch/issues/12018
+#
+# running tests in non-chroot environments:
+# FEATURES="test -usersandbox" emerge dev-python/elasticsearch-curator
+python_test() {
+	ES="${WORKDIR}/elasticsearch-${ES_VERSION}"
+	ES_PORT="25123"
+	ES_INSTANCE="gentoo-es-curator-test"
+	ES_LOG="${ES}/logs/${ES_INSTANCE}.log"
+	PID="${ES}/elasticsearch.pid"
+
+	# run Elasticsearch instance on custom port
+	sed -i "s/#http.port: 9200/http.port: ${ES_PORT}/g; \
+		s/#cluster.name: my-application/cluster.name: ${ES_INSTANCE}/g" \
+		"${ES}/config/elasticsearch.yml" || die
+
+	# start local instance of elasticsearch
+	"${ES}/bin/elasticsearch" -d -p "${PID}" -Epath.repo=/ || die
+
+	local i
+	local es_started=0
+	for i in {1..20}; do
+		grep -q "started" "${ES_LOG}" 2> /dev/null
+		if [[ $? -eq 0 ]]; then
+			einfo "Elasticsearch started"
+			es_started=1
+			eend 0
+			break
+		elif grep -q 'BindException\[Address already in use\]' "${ES_LOG}" 2>/dev/null; then
+			eend 1
+			eerror "Elasticsearch already running"
+			die "Cannot start Elasticsearch for tests"
+		else
+			einfo "Waiting for Elasticsearch"
+			eend 1
+			sleep 2
+			continue
+		fi
+	done
+
+	[[ $es_started -eq 0 ]] && die "Elasticsearch failed to start"
+
+	export TEST_ES_SERVER="localhost:${ES_PORT}"
+	esetup.py test || die
+
+	pkill -F ${PID}
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	doman docs/_build/man/*
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	ewarn ""
+	ewarn "For Python 3 support information please read: http://click.pocoo.org/latest/python3/"
+	ewarn ""
+	ewarn "Example usage on Python 3:"
+	ewarn "export LC_ALL=en_US.UTF-8"
+	ewarn "export LANG=en_US.UTF-8"
+	ewarn "curator ..."
+}