dev-libs/xalan-c: fix automagic USE=doc

Closes: https://bugs.gentoo.org/882715
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

2 files changed, 60 insertions, 1 deletions

diff --git a/dev-libs/xalan-c/xalan-c-1.12-r1.ebuild b/dev-libs/xalan-c/xalan-c-1.12-r1.ebuild
new file mode 100644
index 000000000000..53dc25c881f6
--- /dev/null
+++ b/dev-libs/xalan-c/xalan-c-1.12-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+MY_PN=${PN/-/_}
+DESCRIPTION="XSLT processor for transforming XML into HTML, text, or other XML types"
+HOMEPAGE="https://apache.github.io/xalan-c/"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/apache/xalan-c.git"
+
+	SLOT="0"
+else
+	inherit verify-sig
+	SRC_URI="
+		mirror://apache/xalan/xalan-c/sources/${MY_PN}-${PV}.tar.gz
+		verify-sig? ( https://dlcdn.apache.org/xalan/xalan-c/sources/${MY_PN}-${PV}.tar.gz.asc )
+	"
+	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/apache-xalan-c.asc
+
+	SLOT="0/$(ver_cut 1-2)"
+	KEYWORDS="~amd64 ~ppc ~x86"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+	BDEPEND="
+		verify-sig? ( sec-keys/openpgp-keys-apache-xalan-c )
+	"
+fi
+
+LICENSE="Apache-2.0"
+IUSE="doc"
+
+RDEPEND="
+	dev-libs/icu:=
+	dev-libs/xerces-c[icu]
+"
+DEPEND="${RDEPEND}"
+BDEPEND+="
+	doc? ( app-doc/doxygen[dot] )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-Ddoxygen=$(usex doc)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use doc; then
+		docinto examples
+		dodoc -r samples/*/
+	fi
+}
diff --git a/dev-libs/xalan-c/xalan-c-9999.ebuild b/dev-libs/xalan-c/xalan-c-9999.ebuild
index c4f9eac0ffdc..53dc25c881f6 100644
--- a/dev-libs/xalan-c/xalan-c-9999.ebuild
+++ b/dev-libs/xalan-c/xalan-c-9999.ebuild
@@ -43,7 +43,7 @@ BDEPEND+="
 
 src_configure() {
 	local mycmakeargs=(
-		-DBUILD_DOXYGEN=$(usex doc)
+		-Ddoxygen=$(usex doc)
 	)
 
 	cmake_src_configure