dev-libs/wayland: Version bump to 1.22.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 68 insertions, 1 deletions

diff --git a/dev-libs/wayland/Manifest b/dev-libs/wayland/Manifest
index b1576035cfe9..49599048a0b7 100644
--- a/dev-libs/wayland/Manifest
+++ b/dev-libs/wayland/Manifest
@@ -1 +1,2 @@
 DIST wayland-1.21.0.tar.xz 225936 BLAKE2B 2b43eb1517d476bb2b4daed1083373655b57d047968fdb93dbbbbe4235af12e25557627e30b5c3d2575bac4beaf1e0a0b8ef10a3c673538d9097501f33c05836 SHA512 5575216d30fdf5c63caa6bcad071e15f2a4f3acb12df776806073f65db37a50b5b5b3cc7957c5497636f4ac01893e2eaab26e453ded44b287acde01762f5fdc3
+DIST wayland-1.22.0.tar.xz 229544 BLAKE2B b0bb366e7f3494813d1574228ae5dd48eccde035120d6dd8709e3a24738681ab9dd9ba6a13924b6a35982d331fa8911fa7346911da9f618be9c9109da0288629 SHA512 fb1974efc8433e97254eb83fe28974198f2b4d8246418eb3d34ce657055461e0c97bc06dd52e5066ae91bbe05bac611dc49a0937ba226ac6388d5a47241efb12
diff --git a/dev-libs/wayland/wayland-1.22.0.ebuild b/dev-libs/wayland/wayland-1.22.0.ebuild
new file mode 100644
index 000000000000..9fe3f14c9121
--- /dev/null
+++ b/dev-libs/wayland/wayland-1.22.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/wayland/wayland.git"
+	inherit git-r3
+else
+	SRC_URI="https://gitlab.freedesktop.org/wayland/${PN}/-/releases/${PV}/downloads/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+inherit meson-multilib
+
+DESCRIPTION="Wayland protocol libraries"
+HOMEPAGE="https://wayland.freedesktop.org/ https://gitlab.freedesktop.org/wayland/wayland"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	~dev-util/wayland-scanner-${PV}
+	virtual/pkgconfig
+	doc? (
+		>=app-doc/doxygen-1.6[dot]
+		app-text/xmlto
+		>=media-gfx/graphviz-2.26.0
+	)
+"
+DEPEND="
+	>=dev-libs/libffi-3.0.13-r1:=[${MULTILIB_USEDEP}]
+"
+RDEPEND="${DEPEND}"
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_bool doc documentation)
+		$(meson_native_true dtd_validation)
+		-Dlibraries=true
+		-Dscanner=false
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# We set it on purpose to only a short subdir name, as socket paths are
+	# created in there, which are 108 byte limited. With this it hopefully
+	# barely fits to the limit with /var/tmp/portage/${CATEGORY}/${PF}/temp/x
+	export XDG_RUNTIME_DIR="${T}"/x
+	mkdir "${XDG_RUNTIME_DIR}" || die
+	chmod 0700 "${XDG_RUNTIME_DIR}" || die
+
+	multilib-minimal_src_test
+}
+
+src_install() {
+	meson-multilib_src_install
+
+	if use doc; then
+		mv "${ED}"/usr/share/doc/"${PN}"/* "${ED}"/usr/share/doc/"${PF}"/ || die
+		rmdir "${ED}"/usr/share/doc/"${PN}" || die
+	fi
+}
diff --git a/dev-libs/wayland/wayland-9999.ebuild b/dev-libs/wayland/wayland-9999.ebuild
index c232ff0e5669..9fe3f14c9121 100644
--- a/dev-libs/wayland/wayland-9999.ebuild
+++ b/dev-libs/wayland/wayland-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8