dev-libs/totem-pl-parser: Bump to 3.26.4

Package-Manager: Portage-2.3.81, Repoman-2.3.19
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 67 insertions, 0 deletions

diff --git a/dev-libs/totem-pl-parser/Manifest b/dev-libs/totem-pl-parser/Manifest
index 592dd0eb75b0..8c826dbfdb9c 100644
--- a/dev-libs/totem-pl-parser/Manifest
+++ b/dev-libs/totem-pl-parser/Manifest
@@ -1 +1,2 @@
 DIST totem-pl-parser-3.26.3.tar.xz 1314216 BLAKE2B 24b1c7e111456b454022ba7262a1e1483420dbd97b6ec99c0e2631acbb8057134b51ff991d2619e6bda57da6c133e211f949915b0fd62d497905fcd58738b43d SHA512 f059fd9447627268ce5029ed48551b0a2b6c30ba28c50a360d37808ad63fa8423824eef29c7f4d7a752f24861d4c7a7139f321fa2e19085085446e7ed15130cd
+DIST totem-pl-parser-3.26.4.tar.xz 1314800 BLAKE2B a069a7b7c394ab5686e827804dd13df06c6af7b8e515e0a0f5023919ecbf720eb8d52643e35bfb99ff4474e67332e072a3c832ef91232bb4108f282b0bc84bce SHA512 afb02a7c70f2fda9cda67b9daa8bab5f15e68a4afd983fb865fb29de71fe8f5c8fdf716e714e3835ac1c3476ce188c6147924a840c4ba82f0c05c3d3c23f5173
diff --git a/dev-libs/totem-pl-parser/totem-pl-parser-3.26.4.ebuild b/dev-libs/totem-pl-parser/totem-pl-parser-3.26.4.ebuild
new file mode 100644
index 000000000000..c9bbdbd5fe9e
--- /dev/null
+++ b/dev-libs/totem-pl-parser/totem-pl-parser-3.26.4.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org meson xdg
+
+DESCRIPTION="Playlist parsing library"
+HOMEPAGE="https://developer.gnome.org/totem-pl-parser/stable/"
+
+LICENSE="LGPL-2+"
+SLOT="0/18"
+IUSE="archive crypt gtk-doc +introspection +quvi test"
+RESTRICT="!test? ( test )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.56:2
+	quvi? ( >=media-libs/libquvi-0.9.1:0= )
+	archive? ( >=app-arch/libarchive-3:0= )
+	dev-libs/libxml2:2
+	crypt? ( dev-libs/libgcrypt:0= )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.14
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? (
+		gnome-base/gvfs[http]
+		sys-apps/dbus )
+"
+
+src_prepare() {
+	# Disable tests requiring network access, bug #346127
+	# 3rd test fails on upgrade, not once installed
+	# Leio: I consider network tests important for ensuring full functionality, thus trying with them again */
+	#sed -e 's:\(g_test_add_func.*/parser/resolution.*\):/*\1*/:' \
+	#	-e 's:\(g_test_add_func.*/parser/parsing/itms_link.*\):/*\1*/:' \
+	#	-e 's:\(g_test_add_func.*/parser/parsability.*\):/*\1*/:'\
+	#	-i plparse/tests/parser.c || die "sed failed"
+
+	xdg_src_prepare
+}
+
+src_configure() {
+	# uninstalled-tests is abused to switch from loading live FS helper
+	# to in-build-tree helper, check on upgrades this is not having other
+	# consequences, bug #630242
+	local emesonargs=(
+		-Denable-quvi=$(usex quvi yes no)
+		-Denable-libarchive=$(usex archive yes no)
+		-Denable-libgcrypt=$(usex crypt yes no)
+		$(meson_use gtk-doc enable-gtk-doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# This is required as told by upstream in bgo#629542
+	GVFS_DISABLE_FUSE=1 dbus-run-session meson test -C "${BUILD_DIR}"
+}