dev-libs/liborcus: 0.19.2 version bump, python3_12

Tests passed.

Bug: https://bugs.gentoo.org/919900
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

3 files changed, 69 insertions, 7 deletions

diff --git a/dev-libs/liborcus/Manifest b/dev-libs/liborcus/Manifest
index a10f5c5f0982..521c0a55f1a7 100644
--- a/dev-libs/liborcus/Manifest
+++ b/dev-libs/liborcus/Manifest
@@ -1 +1,2 @@
 DIST liborcus-0.17.2.tar.xz 1839188 BLAKE2B d274e3af71df16866e305403d63d3978613915753412ac9de19d7de7802930c3886d8653d6d48a8d9a971dc0ee284f8f83af8dc07850b5f28fcdab2815b6d9b2 SHA512 8ad8db46c23673260057aff555286d95ebfeff0a027bdeae24f11f8aa12456284f7f4446edddb91936b3011eb1227cfe1618ab3c4d909f8356c8c151f5739d79
+DIST liborcus-0.19.2.tar.xz 2211268 BLAKE2B 4ee3fd2fb122d3a9840cb92452bf8a6d3d54b7b50a32be84e1bb08dfe2e2abc2de80098d9460b6bd82d0249304a7ba5c39b18ace3f69150ba71e16ef14795ca4 SHA512 c955490f57e91615278a83bb48726025cd5f8059b97ed5532f770199e134ca511c7ee6b0cd0a9d3a2d54208a5fdd19117054e95e818162ea568052fa11b21d4e
diff --git a/dev-libs/liborcus/liborcus-0.19.2.ebuild b/dev-libs/liborcus/liborcus-0.19.2.ebuild
new file mode 100644
index 000000000000..8649b24fcab1
--- /dev/null
+++ b/dev-libs/liborcus/liborcus-0.19.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit autotools python-single-r1
+
+DESCRIPTION="Standalone file import filter library for spreadsheet documents"
+HOMEPAGE="https://gitlab.com/orcus/orcus/blob/master/README.md"
+
+if [[ ${PV} == *9999* ]]; then
+	MDDS_SLOT="1/2.1"
+	EGIT_REPO_URI="https://gitlab.com/orcus/orcus.git"
+	inherit git-r3
+else
+	MDDS_SLOT="1/2.1"
+	SRC_URI="https://kohei.us/files/orcus/src/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/0.18" # based on SONAME of liborcus.so
+IUSE="python +spreadsheet-model test tools"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/boost:=[zlib(+)]
+	sys-libs/zlib
+	python? ( ${PYTHON_DEPS} )
+	spreadsheet-model? ( dev-libs/libixion:${SLOT} )
+"
+DEPEND="${RDEPEND}
+	dev-util/mdds:${MDDS_SLOT}
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-werror
+		$(use_enable python)
+		$(use_enable spreadsheet-model)
+		$(use_with tools)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	python_optimize
+	find "${D}" -name '*.la' -type f -delete || die
+}
diff --git a/dev-libs/liborcus/liborcus-9999.ebuild b/dev-libs/liborcus/liborcus-9999.ebuild
index 53b0600bb160..a23ce4dca5a3 100644
--- a/dev-libs/liborcus/liborcus-9999.ebuild
+++ b/dev-libs/liborcus/liborcus-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_COMPAT=( python3_{10..12} )
 inherit autotools python-single-r1
 
 DESCRIPTION="Standalone file import filter library for spreadsheet documents"
@@ -14,9 +14,9 @@ if [[ ${PV} == *9999* ]]; then
 	EGIT_REPO_URI="https://gitlab.com/orcus/orcus.git"
 	inherit git-r3
 else
-	MDDS_SLOT="1/2.0"
+	MDDS_SLOT="1/2.1"
 	SRC_URI="https://kohei.us/files/orcus/src/${P}.tar.xz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~x86"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
 fi
 
 LICENSE="MIT"
@@ -41,15 +41,13 @@ pkg_setup() {
 }
 
 src_prepare() {
-	# bug 713586
-	use test && eapply "${FILESDIR}/${P}-test-fix.patch"
-
 	default
 	eautoreconf
 }
 
 src_configure() {
 	local myeconfargs=(
+		--without-benchmark
 		--disable-werror
 		$(use_enable python)
 		$(use_enable spreadsheet-model)
@@ -60,5 +58,6 @@ src_configure() {
 
 src_install() {
 	default
+	python_optimize
 	find "${D}" -name '*.la' -type f -delete || die
 }