dev-libs/libltdl: add 2.4.7 (unkeyworded)

Unkeyworded like new sys-devel/libtool for testing, as it's been a looong
time since the last release, although less changed wrt
libltdl, actually - it's still cut from the same tarball nonetheless.

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 36 insertions, 0 deletions

diff --git a/dev-libs/libltdl/libltdl-2.4.7.ebuild b/dev-libs/libltdl/libltdl-2.4.7.ebuild
new file mode 100644
index 000000000000..766091c456e4
--- /dev/null
+++ b/dev-libs/libltdl/libltdl-2.4.7.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+MY_P="libtool-${PV}"
+
+DESCRIPTION="A shared library tool for developers"
+HOMEPAGE="https://www.gnu.org/software/libtool/"
+SRC_URI="mirror://gnu/libtool/${MY_P}.tar.xz"
+S="${WORKDIR}"/${MY_P}/libltdl
+
+LICENSE="GPL-2"
+SLOT="0"
+#KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="static-libs"
+# libltdl doesn't have a testsuite.
+
+RDEPEND="!<sys-devel/libtool-2.4.3-r2:2"
+BDEPEND="app-arch/xz-utils"
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		--enable-ltdl-install \
+		$(use_enable static-libs static)
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	# While the libltdl.la file is not used directly, the m4 ltdl logic
+	# keys off of its existence when searching for ltdl support. # bug #293921
+	#use static-libs || find "${D}" -name libltdl.la -delete
+}