dev-libs/libinput: add 1.22.1

Closes: https://bugs.gentoo.org/889908
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index 34737fce87c8..3ee0d562b1de 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1,2 +1,3 @@
 DIST libinput-1.21.0.tar.gz 988650 BLAKE2B 54c63beeff8dee93a52774220b45321d8a94261687b463319fbae9246331b532be7995a5b32c30425b9d0708b2ba69d4b4e83e8dc7ecebe6fb1237b723a266b6 SHA512 510273d68f2d4cfa61564a706b1f334f6bfca0d1c8faf0bb8aa656cf3fbd5e38d79d6fbaa01a20d38bc15777c9afc341e4ed08d35ef367ef3803ce788cbc4a0e
 DIST libinput-1.22.0.tar.bz2 796133 BLAKE2B 3552f0a9ab0690969c5a7d62882733aa7bcaed1c0e97ff3606f58558c235cb67e3c81bc5a277273d26e6847438acccfc942d2fbec312e9a0d121d8ea21896496 SHA512 62cc36845daa7bc4b8477dd71abe629309683a93de753382a90e8466915e2b96b9c6914b431747d3462c15d8ab42bc70ee755800eec60c4ad7e9f3b4f7dba76d
+DIST libinput-1.22.1.tar.bz2 794829 BLAKE2B 253f840e45ab2293503a0da09ea914b982e643c35928af6762955325a002b5bf20bf8571e705e3a050663cd0e1e26ee0cf4952a6193659f9b27ad1080008e900 SHA512 9d1985bc03ae304643fcd3acb762afc53305942e39071a062e7f8950be4929c72bdfeff06039c77f70e53233885df1e2e1a1dc538caeefd2b46f35826d290e9e
diff --git a/dev-libs/libinput/libinput-1.22.1.ebuild b/dev-libs/libinput/libinput-1.22.1.ebuild
new file mode 100644
index 000000000000..a6741dc43f7b
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.22.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 2014-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit meson optfeature python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0/10"
+if [[ $(ver_cut 3) -lt 900 ]] ; then
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+IUSE="doc input_devices_wacom test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	input_devices_wacom? ( >=dev-libs/libwacom-0.27:= )
+	>=dev-libs/libevdev-1.9.902
+	>=sys-libs/mtdev-1.1
+	virtual/libudev:=
+	virtual/udev
+"
+DEPEND="
+	${RDEPEND}
+	test? ( >=dev-libs/check-0.9.10 )
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/commonmark[${PYTHON_USEDEP}]
+			dev-python/recommonmark[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+		')
+		>=app-doc/doxygen-1.8.3
+		>=media-gfx/graphviz-2.38.0
+	)
+"
+#	test? ( dev-util/valgrind )
+
+python_check_deps() {
+	python_has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+	python_has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+	python_has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed "s@, '-Werror'@@" -i meson.build || die #744250
+}
+
+src_configure() {
+	# gui can be built but will not be installed
+	local emesonargs=(
+		-Ddebug-gui=false
+		$(meson_use doc documentation)
+		$(meson_use input_devices_wacom libwacom)
+		$(meson_use test tests)
+		-Dudev-dir="${EPREFIX}$(get_udevdir)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc ; then
+		docinto html
+		dodoc -r "${BUILD_DIR}"/Documentation/.
+	fi
+}
+
+pkg_postinst() {
+	optfeature "measure and replay tools" dev-python/python-libevdev
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}