app-text/poppler: Drop 0.86.0 (r0)

Package-Manager: Portage-2.3.95, Repoman-2.3.21
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 124 deletions

diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index c0d2a7e491bc..13b0908b6322 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -1,4 +1,3 @@
 DIST poppler-0.82.0.tar.xz 1553336 BLAKE2B a83d476ce1174cb7789f857a52a8a9ed29dfe8863d082ef662508ad9957667349aa62b038fa1a52e9e7ae3ddf4701eb5fbd58545b041b6aebd69cb8b91376d8d SHA512 1631be30e398dd18a4e8c2cc893cf0d9469a98d93f02f2ffe3bc14857518b76674a10cafe89ee92b9886c3c6b03d50e214a6838c102f673a62789c9832cfa4a2
 DIST poppler-0.85.0.tar.xz 1588616 BLAKE2B d30c16ff214d2b64fade28bb4099567150e99df6ab967702f48e18ed2191e444728f51d4c1ce1772567c31f9b87a8cf64993ebc383184e06f8b3707436c89143 SHA512 2311bde5ae52e065c12a6129f500469860f5ebefafc3f7be581393f08c2121f3eae57394ff54c1f83ee1b926f28c61530bcd8149d42de10a16b9ba7345f2604e
-DIST poppler-0.86.0.tar.xz 1593992 BLAKE2B 7b09d3d173db31a3dc2965e7eb5dc80fe1e714a7f1319b5fce0719ea345f496313536da023da8f7793d7365210159b26ea23ae95bdef709efbe665abeb13fdb9 SHA512 58a8ee7bc0bae1dfbbd1bd8d2f66bbb77bd4b93637f500b7d69f4b57d20f7f14b2b23b74f2e34a3f00c7b7887c366379ed6d95f5e1e610eafb9cf7847ea7583a
 DIST poppler-0.86.1.tar.xz 1593856 BLAKE2B f39a3113d8d33480b186173dade5305ad8157b38df579e18f6a05ae48e449259aeb9788e1c94ab3b43fae9bb027655e4e3072ddf8a6dc9ccdef93262def62160 SHA512 435fc1e7f3e8123e0adde9aa60c0d7dc17db367cde8908932abfef913cee6f27efeb1c4f2d6f316019a69a87f1fa5251be4216d0a81a681a24f24a70ac571670
diff --git a/app-text/poppler/poppler-0.86.0.ebuild b/app-text/poppler/poppler-0.86.0.ebuild
deleted file mode 100644
index 4b6016d93eb8..000000000000
--- a/app-text/poppler/poppler-0.86.0.ebuild
+++ /dev/null
@@ -1,123 +0,0 @@
-# Copyright 2005-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit cmake toolchain-funcs xdg-utils
-
-if [[ ${PV} == *9999* ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
-	SLOT="0/9999"
-else
-	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-	SLOT="0/96"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
-fi
-
-DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
-HOMEPAGE="https://poppler.freedesktop.org/"
-
-LICENSE="GPL-2"
-IUSE="cairo cjk curl +cxx debug doc +introspection +jpeg +jpeg2k +lcms nss png qt5 tiff +utils"
-
-# No test data provided
-RESTRICT="test"
-
-BDEPEND="
-	dev-util/glib-utils
-	virtual/pkgconfig
-"
-DEPEND="
-	media-libs/fontconfig
-	media-libs/freetype
-	sys-libs/zlib
-	cairo? (
-		dev-libs/glib:2
-		x11-libs/cairo
-		introspection? ( dev-libs/gobject-introspection:= )
-	)
-	curl? ( net-misc/curl )
-	jpeg? ( virtual/jpeg:0 )
-	jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
-	lcms? ( media-libs/lcms:2 )
-	nss? ( >=dev-libs/nss-3.19:0 )
-	png? ( media-libs/libpng:0= )
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtxml:5
-	)
-	tiff? ( media-libs/tiff:0 )
-"
-RDEPEND="${DEPEND}
-	cjk? ( app-text/poppler-data )
-"
-
-DOCS=( AUTHORS NEWS README.md README-XPDF )
-
-PATCHES=(
-	"${FILESDIR}/${PN}-0.60.1-qt5-dependencies.patch"
-	"${FILESDIR}/${PN}-0.28.1-fix-multilib-configuration.patch"
-	"${FILESDIR}/${PN}-0.82.0-respect-cflags.patch"
-	"${FILESDIR}/${PN}-0.61.0-respect-cflags.patch"
-	"${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
-)
-
-src_prepare() {
-	cmake_src_prepare
-
-	# Clang doesn't grok this flag, the configure nicely tests that, but
-	# cmake just uses it, so remove it if we use clang
-	if [[ ${CC} == clang ]] ; then
-		sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
-	fi
-
-	if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
-		sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
-			-i CMakeLists.txt || die
-	else
-		einfo "policy(SET CMP0002 OLD) - workaround can be removed"
-	fi
-}
-
-src_configure() {
-	xdg_environment_reset
-	local mycmakeargs=(
-		-DBUILD_GTK_TESTS=OFF
-		-DBUILD_QT5_TESTS=OFF
-		-DBUILD_CPP_TESTS=OFF
-		-DRUN_GPERF_IF_PRESENT=OFF
-		-DENABLE_SPLASH=ON
-		-DENABLE_ZLIB=ON
-		-DENABLE_ZLIB_UNCOMPRESS=OFF
-		-DENABLE_UNSTABLE_API_ABI_HEADERS=ON
-		-DUSE_FLOAT=OFF
-		-DWITH_Cairo=$(usex cairo)
-		-DENABLE_LIBCURL=$(usex curl)
-		-DENABLE_CPP=$(usex cxx)
-		-DWITH_JPEG=$(usex jpeg)
-		-DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
-		-DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
-		-DENABLE_CMS=$(usex lcms lcms2 none)
-		-DWITH_NSS3=$(usex nss)
-		-DWITH_PNG=$(usex png)
-		$(cmake_use_find_package qt5 Qt5Core)
-		-DWITH_TIFF=$(usex tiff)
-		-DENABLE_UTILS=$(usex utils)
-	)
-	use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
-
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	# live version doesn't provide html documentation
-	if use cairo && use doc && [[ ${PV} != *9999* ]]; then
-		# For now install gtk-doc there
-		insinto /usr/share/gtk-doc/html/poppler
-		doins -r "${S}"/glib/reference/html/*
-	fi
-}