app-misc/gnote: Version bump to 42.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 67 insertions, 0 deletions

diff --git a/app-misc/gnote/Manifest b/app-misc/gnote/Manifest
index 90e6f7154489..ce0a73667006 100644
--- a/app-misc/gnote/Manifest
+++ b/app-misc/gnote/Manifest
@@ -1 +1,2 @@
 DIST gnote-40.2.tar.xz 3422560 BLAKE2B d7d7fa862e02c1d889c736ae733db503a06db93cfc79c12bd1efa89acbe4a5825d0cf0cab00cfa916566002c1b838d118b37f5b0204f20ac9fcab2f892cccf52 SHA512 e1dc3ed4fb7b7c4f346a4a1e63a2e357b197375caf5d1d2026c159cfda012ace76ad598ecaf8e7d7649fb80abedc0cd4febd369160ddaf4510cfcc6b41185aed
+DIST gnote-42.0.tar.xz 3330504 BLAKE2B 847c1c66b86902c13a7e9cd349e0b1e565f046ba81809dca002bfdc07d1e3dc4e12797da90e7689d8fde886ced580da9b744ca736697d1fd933a93cc344304bd SHA512 fcdd653a29ae957faf177bacbe1bbdced186416c04a8f45f194a055914544b0679019935f482834e515a20865f358dfdfc32aa846c0fd24596cf5e569e21b997
diff --git a/app-misc/gnote/gnote-42.0.ebuild b/app-misc/gnote/gnote-42.0.ebuild
new file mode 100644
index 000000000000..ffd488033aaf
--- /dev/null
+++ b/app-misc/gnote/gnote-42.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2 meson readme.gentoo-r1
+
+DESCRIPTION="Desktop note-taking application"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gnote"
+
+LICENSE="GPL-3+ FDL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/glib-2.62:2[dbus]
+	>=dev-cpp/glibmm-2.62.0:2
+	>=dev-cpp/gtkmm-3.22.20:3.0
+	>=app-crypt/libsecret-0.8
+	>=dev-libs/libxml2-2:2
+	dev-libs/libxslt
+	>=sys-apps/util-linux-2.16:=
+	>=app-text/gspell-1.6.0:=
+	test? ( dev-libs/unittest++ )
+"
+RDEPEND="${DEPEND}
+	gnome-base/gsettings-desktop-schemas
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	>=dev-util/intltool-0.35.0
+	dev-util/itstool
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	# Build system requires UnitTest++ >=1.5.1, but the .pc file doesn't
+	# specify a version
+	sed -i -e "/UnitTest++/ s/version: [^,]*,//" meson.build || die
+	if ! use test; then
+		sed -i -e "/unit_test_pp/ s/ = .*/ = disabler()/" meson.build || die
+	fi
+
+	if has_version net-fs/wdfs; then
+		DOC_CONTENTS="You have net-fs/wdfs installed. app-misc/gnote will use it to
+		synchronize notes."
+	else
+		DOC_CONTENTS="Gnote can use net-fs/wdfs to synchronize notes.
+		If you want to use that functionality just emerge net-fs/wdfs.
+		Gnote will automatically detect that you did and let you use it."
+	fi
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}