app-i18n/xvnkb: Port to EAPI 7

Bug: https://bugs.gentoo.org/697382
Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 22 insertions, 28 deletions

diff --git a/app-i18n/xvnkb/xvnkb-0.2.9a-r1.ebuild b/app-i18n/xvnkb/xvnkb-0.2.9a-r1.ebuild
index 3011a7130047..3f52d6d81c32 100644
--- a/app-i18n/xvnkb/xvnkb-0.2.9a-r1.ebuild
+++ b/app-i18n/xvnkb/xvnkb-0.2.9a-r1.ebuild
@@ -1,57 +1,50 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=0
+EAPI=7
 
-inherit eutils multilib toolchain-funcs
-
-IUSE="spell xft"
+inherit toolchain-funcs
 
 DESCRIPTION="Vietnamese input keyboard for X"
 SRC_URI="http://xvnkb.sourceforge.net/${P}.tar.bz2"
 HOMEPAGE="http://xvnkb.sourceforge.net/"
 
 LICENSE="GPL-2"
-
 SLOT="0"
-KEYWORDS="amd64 ~ppc x86"
-RDEPEND="x11-libs/libX11
-	xft? ( x11-libs/libXft )"
-DEPEND="${RDEPEND}
-	x11-base/xorg-proto"
+KEYWORDS="amd64 ppc x86"
+IUSE="spell xft"
 
-src_unpack() {
-	unpack ${A}
-	cd "${S}"
-	epatch "${FILESDIR}"/${P}-ldflags.patch
-}
+RDEPEND="
+	x11-libs/libX11:=
+	xft? ( x11-libs/libXft:= )"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto"
 
-src_compile() {
-	local myconf
+PATCHES=( "${FILESDIR}"/${P}-ldflags.patch )
 
+src_configure() {
 	tc-export CC
 
-	use spell || myconf="${myconf} --no-spellcheck"
-	use xft || myconf="${myconf} --no-xft"
+	local myconf=()
+	! use spell && myconf+=( --no-spellcheck )
+	! use xft && myconf+=( --no-xft )
 
 	# *not* autotools
 	./configure \
-		--use-extstroke ${myconf} \
+		--use-extstroke "${myconf[@]}" \
 		|| die "./configure failed"
-
-	emake || die "emake failed"
 }
 
 src_install() {
 	dobin xvnkb
 	dobin tools/xvnkb_ctrl
 
-	dolib xvnkb.so.${PV}
+	dolib.so xvnkb.so.${PV}
 	dosym xvnkb.so.${PV} /usr/$(get_libdir)/xvnkb.so
 
-	dodoc ChangeLog AUTHORS THANKS TODO README* doc/*
-	docinto scripts; dodoc scripts/*
-	docinto contrib; dodoc contrib/*
+	einstalldocs
+	dodoc -r doc/. scripts contrib
 }
 
 pkg_postinst() {
@@ -60,7 +53,8 @@ pkg_postinst() {
 	elog "(or any other UTF-8 locale) and"
 	elog "$ export LD_PRELOAD=/usr/$(get_libdir)/xvnkb.so"
 	elog "before starting X Window"
-	elog "More documents are in /usr/share/doc/${PF}"
+	elog "More documents are in ${EROOT}/usr/share/doc/${PF}"
+
 	ewarn "Programs with suid/sgid will have LD_PRELOAD cleared"
 	ewarn "You have to unset suid/sgid to use with xvnkb"
 }