app-cdr/dolphin-plugins-mountiso: 23.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/app-cdr/dolphin-plugins-mountiso/Manifest b/app-cdr/dolphin-plugins-mountiso/Manifest
index 53a35785d07a..09e4ebe4aa75 100644
--- a/app-cdr/dolphin-plugins-mountiso/Manifest
+++ b/app-cdr/dolphin-plugins-mountiso/Manifest
@@ -1 +1,2 @@
 DIST dolphin-plugins-23.04.3.tar.xz 272912 BLAKE2B f0eb8bbab16d66f1e964131b436af7d3ae8febc26cf4fe394489a978c701ef2f5689bea7daf9eed8d7ef2f1f2bdba000a487cf7f0704ad30bd25e2d403ce5fae SHA512 8f487ba0bcbe561915064247ddb2327c3b7c8fa6ffc5c511d9c9ef37bd4f28a624533ce7a2da2a86b10b65f37915ca10840517872b40c2fd014cead6da5972c8
+DIST dolphin-plugins-23.08.0.tar.xz 273412 BLAKE2B edd20bb433b5288cc5687009cfd65d978b98de6b81dbc9b8aeb598a84411f67557e72be5212844852ce4cd7ecdd9d092e003603dfe8e6b6a5a2a30d94fbb3f58 SHA512 4abf6e41c6a4755117446ac744779ca7acdf1f1380cffa5be9931fc1463073b20c3c0b26a20de86befb49541f04523aedb8114189d68413bb75317d98ee54615
diff --git a/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-23.08.0.ebuild b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-23.08.0.ebuild
new file mode 100644
index 000000000000..34df875e54e2
--- /dev/null
+++ b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-23.08.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="false"
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+	# delete non-${PN} translations
+	find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}