app-admin/keepassxc: Bump to version 2.7.0_beta1

Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 97 insertions, 0 deletions

diff --git a/app-admin/keepassxc/Manifest b/app-admin/keepassxc/Manifest
index cfe9fe1f233c..2e6bcf95b9b0 100644
--- a/app-admin/keepassxc/Manifest
+++ b/app-admin/keepassxc/Manifest
@@ -1 +1,2 @@
 DIST keepassxc-2.6.6-src.tar.xz 7640532 BLAKE2B ed55dfe992c02e78354d7aeb9f63853380dbcdec0e834232997cb6f5ecc303ff18ed50dcc48f54497031d6fc8b741c620202e78c3eacbe50d4dcfa7e4d59a92c SHA512 175702ef3ae5b048ba23a794ddf4e17d61f2640955de7ec21a3e49e4abe7cab8c93c9a2bc61c5c052c62382a69bd8dcb4a4f0cf6daa162f5e00cff3f7a1a713b
+DIST keepassxc-2.7.0_beta1.tar.gz 10634757 BLAKE2B 3ec079dacbf6f13f60ac68084d167e90f213894f3141a55962720646673de0bf466c81493a4f449b4871298d8067b1971e7e25477b7cbecb47a277e5594b425e SHA512 b1fbdf5afea1514a8e42338ea26077b0a6d3088674baf1761e8ac0060ffd5c14da6f7bf11d31cd04f90d02c30e6db39e559c2995863cb3f563d7e6894f7680a9
diff --git a/app-admin/keepassxc/keepassxc-2.7.0_beta1.ebuild b/app-admin/keepassxc/keepassxc-2.7.0_beta1.ebuild
new file mode 100644
index 000000000000..3d0e25a306e7
--- /dev/null
+++ b/app-admin/keepassxc/keepassxc-2.7.0_beta1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic xdg
+
+DESCRIPTION="KeePassXC - KeePass Cross-platform Community Edition"
+HOMEPAGE="https://keepassxc.org"
+
+if [[ "${PV}" != *9999 ]] ; then
+	if [[ "${PV}" == *_beta* ]] ; then
+		SRC_URI="https://github.com/keepassxreboot/keepassxc/archive/${PV/_/-}.tar.gz -> ${P}.tar.gz"
+		S="${WORKDIR}/${P/_/-}"
+	else
+		#SRC_URI="https://github.com/keepassxreboot/keepassxc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+		SRC_URI="https://github.com/keepassxreboot/keepassxc/releases/download/${PV}/${P}-src.tar.xz"
+		KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+	fi
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/keepassxreboot/${PN}"
+	[[ "${PV}" != 9999 ]] && EGIT_BRANCH="master"
+fi
+
+LICENSE="LGPL-2.1 GPL-2 GPL-3"
+SLOT="0"
+IUSE="autotype browser ccache doc keeshare +network test yubikey"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/botan:2
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	media-gfx/qrencode:=
+	sys-libs/readline:0=
+	sys-libs/zlib:=
+	autotype? (
+		dev-qt/qtx11extras:5
+		x11-libs/libX11
+		x11-libs/libXtst
+	)
+	keeshare? ( sys-libs/zlib:=[minizip] )
+	yubikey? (
+		dev-libs/libusb:1
+		sys-apps/pcsc-lite
+	)
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-qt/linguist-tools:5
+	dev-qt/qttest:5
+"
+BDEPEND="
+	ccache? ( dev-util/ccache )
+	doc? ( dev-ruby/asciidoctor )
+"
+
+src_prepare() {
+	if [[ "${PV}" != *_beta* ]] && [[ "${PV}" != *9999 ]] && [[ ! -f .version ]] ; then
+		printf '%s' "${PV}" > .version || die
+	fi
+
+	 cmake_src_prepare
+}
+
+src_configure() {
+	# https://github.com/keepassxreboot/keepassxc/issues/5801
+	filter-flags -flto*
+
+	local mycmakeargs=(
+		-DWITH_CCACHE="$(usex ccache)"
+		-DWITH_GUI_TESTS=OFF
+		-DWITH_TESTS="$(usex test)"
+		-DWITH_XC_AUTOTYPE="$(usex autotype)"
+		-DWITH_XC_DOCS="$(usex doc)"
+		-DWITH_XC_BROWSER="$(usex browser)"
+		-DWITH_XC_FDOSECRETS=ON
+		-DWITH_XC_KEESHARE="$(usex keeshare)"
+		-DWITH_XC_NETWORKING="$(usex network)"
+		-DWITH_XC_SSHAGENT=ON
+		-DWITH_XC_UPDATECHECK=OFF
+		-DWITH_XC_YUBIKEY="$(usex yubikey)"
+	)
+	if [[ "${PV}" == *_beta* ]] ; then
+		mycmakeargs+=( -DOVERRIDE_VERSION="${PV/_/-}" )
+	fi
+	cmake_src_configure
+}