app-admin/salt: Remove 2017.7.5

Package-Manager: Portage-2.3.41, Repoman-2.3.9

2 files changed, 0 insertions, 155 deletions

diff --git a/app-admin/salt/Manifest b/app-admin/salt/Manifest
index 47ae1b2933c1..d2a7360c6403 100644
--- a/app-admin/salt/Manifest
+++ b/app-admin/salt/Manifest
@@ -1,4 +1,3 @@
 DIST salt-2016.11.9.tar.gz 10062996 BLAKE2B 5176d04d07a69de21c9c136c201d334614c5675fd78e306a0160fae829b633441cd859f4ba1a0822dfbb9ae716475c53f6eb058187d4acc8a5770dd4ceace577 SHA512 896fd27c111e926e246b51d00b69d41c8f4d25ec0c034c9ff3dc5414f5e93592fd637cdeaecf02b3b98a4e5a7ce478bfda86b15497961078374608d76516593d
-DIST salt-2017.7.5.tar.gz 11043026 BLAKE2B 9cae4e6ca3b0bac0dc0b9b9a5ae01e0bfb8e8b899aa029b324ac10c8c84024bbc419ace068cd0d2bff84ec6ddf1d13faf68ce34c68c19892c700c38e81da8c7c SHA512 684ffde7d98c73349b386c94de3d9fc09631a78c5d74e37e6dfd90fbb0c94decc529f56b1eba1559ce9932b16083f88e6495ff6cdf071b32a23028e9db47cc3d
 DIST salt-2017.7.7.tar.gz 11131480 BLAKE2B ea01c8894433cf96697c830d58184bfefca52dcd1be9b1c398270acc229886eeb41edf83d1498fc500f23209fc4e56ba8471da88383bd4c1a9338262423477fb SHA512 01cba364e2dcb5021b2b3b738462645c84332bbf31c0fa82f017fc583a097dccde308fd86be54d2b429921f34c89a4a40b942385c3bc139eb11753d155664063
 DIST salt-2018.3.2.tar.gz 12996445 BLAKE2B 8411fb0891e23ce8e35157662a0a45c0c5b13b62f3fd21cc4bbe5152f923a98b27cb5bee4fb8cb3e6ec5c9daed1afa27baf4b570b94f9f40eddc0891f72829e9 SHA512 142ebe13638d7e6dd0aecc9f0325002d30e115fe8688f5f74cbeb7ff21020327d65ded0dcd845e55362b97568b696887fa22243d66d5eadef65f97152d4775d3
diff --git a/app-admin/salt/salt-2017.7.5.ebuild b/app-admin/salt/salt-2017.7.5.ebuild
deleted file mode 100644
index 90c568f5533f..000000000000
--- a/app-admin/salt/salt-2017.7.5.ebuild
+++ /dev/null
@@ -1,154 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-PYTHON_COMPAT=( python2_7 )
-
-inherit eutils systemd distutils-r1
-
-DESCRIPTION="Salt is a remote execution and configuration manager"
-HOMEPAGE="http://saltstack.org/"
-
-if [[ ${PV} == 9999* ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="git://github.com/${PN}stack/${PN}.git"
-	EGIT_BRANCH="develop"
-	SRC_URI=""
-	KEYWORDS=""
-else
-	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-	KEYWORDS="~x86 ~amd64"
-fi
-
-LICENSE="Apache-2.0"
-SLOT="0"
-IUSE="cherrypy ldap libcloud libvirt gnupg keyring mako mongodb mysql neutron nova"
-IUSE+=" openssl portage profile redis selinux test timelib raet +zeromq vim-syntax"
-
-RDEPEND="sys-apps/pciutils
-	dev-python/jinja[${PYTHON_USEDEP}]
-	>=dev-python/msgpack-0.3[${PYTHON_USEDEP}]
-	<dev-python/msgpack-0.5.5[${PYTHON_USEDEP}]
-	dev-python/pyyaml[${PYTHON_USEDEP}]
-	dev-python/markupsafe[${PYTHON_USEDEP}]
-	>=dev-python/requests-1.0.0[${PYTHON_USEDEP}]
-	dev-python/setuptools[${PYTHON_USEDEP}]
-	>=www-servers/tornado-4.2.1[${PYTHON_USEDEP}]
-	<www-servers/tornado-5.0[${PYTHON_USEDEP}]
-	virtual/python-futures[${PYTHON_USEDEP}]
-	libcloud? ( >=dev-python/libcloud-0.14.0[${PYTHON_USEDEP}] )
-	mako? ( dev-python/mako[${PYTHON_USEDEP}] )
-	ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
-	libvirt? ( dev-python/libvirt-python[${PYTHON_USEDEP}] )
-	openssl? (
-		dev-libs/openssl:*[-bindist]
-		dev-python/pyopenssl[${PYTHON_USEDEP}]
-	)
-	raet? (
-		>=dev-python/libnacl-1.0.0[${PYTHON_USEDEP}]
-		>=dev-python/ioflo-1.1.7[${PYTHON_USEDEP}]
-		>=dev-python/raet-0.6.0[${PYTHON_USEDEP}]
-	)
-	zeromq? (
-		>=dev-python/pyzmq-2.2.0[${PYTHON_USEDEP}]
-		|| (
-			dev-python/pycryptodome[${PYTHON_USEDEP}]
-			>=dev-python/pycrypto-2.6.1[${PYTHON_USEDEP}]
-		)
-	)
-	cherrypy? ( >=dev-python/cherrypy-3.2.2[${PYTHON_USEDEP}] )
-	mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
-	portage? (
-		|| (
-			sys-apps/portage[${PYTHON_USEDEP}]
-			sys-apps/portage-mgorny[${PYTHON_USEDEP}]
-		)
-	)
-	keyring? ( dev-python/keyring[${PYTHON_USEDEP}] )
-	mysql? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
-	redis? ( dev-python/redis-py[${PYTHON_USEDEP}] )
-	selinux? ( sec-policy/selinux-salt )
-	timelib? ( dev-python/timelib[${PYTHON_USEDEP}] )
-	nova? ( >=dev-python/python-novaclient-2.17.0[${PYTHON_USEDEP}] )
-	neutron? ( >=dev-python/python-neutronclient-2.3.6[${PYTHON_USEDEP}] )
-	gnupg? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
-	profile? ( dev-python/yappi[${PYTHON_USEDEP}] )
-	vim-syntax? ( app-vim/salt-vim )"
-DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
-	test? (
-		dev-python/pytest-salt[${PYTHON_USEDEP}]
-		dev-python/psutil[${PYTHON_USEDEP}]
-		dev-python/pytest[${PYTHON_USEDEP}]
-		dev-python/pip[${PYTHON_USEDEP}]
-		dev-python/virtualenv[${PYTHON_USEDEP}]
-		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
-		dev-python/timelib[${PYTHON_USEDEP}]
-		>=dev-python/boto-2.32.1[${PYTHON_USEDEP}]
-		!x86? ( >=dev-python/boto3-1.2.1[${PYTHON_USEDEP}] )
-		>=dev-python/moto-0.3.6[${PYTHON_USEDEP}]
-		>=dev-python/SaltTesting-2016.5.11[${PYTHON_USEDEP}]
-		>=dev-python/libcloud-0.14.0[${PYTHON_USEDEP}]
-		${RDEPEND}
-	)"
-
-DOCS=( README.rst AUTHORS )
-
-REQUIRED_USE="|| ( raet zeromq )"
-RESTRICT="x86? ( test )"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-2017.7.0-dont-realpath-tmpdir.patch"
-	"${FILESDIR}/${PN}-2017.7.3-tests.patch"
-)
-
-python_prepare() {
-	rm tests/unit/{test_zypp_plugins.py,utils/test_extend.py} || die
-	rm tests/unit/modules/test_boto_{vpc,secgroup,elb}.py || die
-	rm tests/unit/states/test_boto_vpc.py || die
-	rm tests/unit/modules/test_kubernetes.py || die
-	# allow the use of the renamed msgpack
-	sed -i '/^msgpack/d' requirements/base.txt || die
-}
-
-python_install_all() {
-	local svc
-	USE_SETUPTOOLS=1 distutils-r1_python_install_all
-
-	for svc in minion master syndic api; do
-		newinitd "${FILESDIR}"/${svc}-initd-4 salt-${svc}
-		newconfd "${FILESDIR}"/${svc}-confd-1 salt-${svc}
-		systemd_dounit "${FILESDIR}"/salt-${svc}.service
-	done
-
-	insinto /etc/${PN}
-	doins -r conf/*
-}
-
-python_test() {
-	local tempdir
-	# testsuite likes lots of files
-	ulimit -n 3072 || die
-
-	# ${T} is too long a path for the tests to work
-	tempdir="$(mktemp -du --tmpdir=/tmp salt-XXX)"
-	mkdir "${T}/$(basename "${tempdir}")"
-	mkdir "${BUILD_DIR}"/../{templates,conf/cloud.{providers,profiles,maps}.d} || die
-
-	(
-		cleanup() {
-			rm -f "${tempdir}"
-			rmdir "${BUILD_DIR}"/../{templates,conf/cloud.{providers,profiles,maps}.d} || die
-		}
-
-		trap cleanup EXIT
-
-		addwrite "${tempdir}"
-		ln -s "$(realpath --relative-to=/tmp "${T}/$(basename "${tempdir}")")" "${tempdir}"
-
-		USE_SETUPTOOLS=1 SHELL="/bin/bash" \
-			TMPDIR="${tempdir}" \
-			${EPYTHON} tests/runtests.py \
-			--unit-tests --no-report --verbose
-
-	) || die "testing failed"
-}