app-crypt/libsecret: bump to 0.18.6

Package-Manager: Portage-2.3.28, Repoman-2.3.9

2 files changed, 78 insertions, 0 deletions

diff --git a/app-crypt/libsecret/Manifest b/app-crypt/libsecret/Manifest
index 7002842744cc..892b339509ba 100644
--- a/app-crypt/libsecret/Manifest
+++ b/app-crypt/libsecret/Manifest
@@ -1 +1,2 @@
 DIST libsecret-0.18.5.tar.xz 508556 BLAKE2B e3410dd113dfa1f4ebb78a47f90e23455eb8f82466d4607aa469c04adc84aa3181bfdb7dcb4ff459fd2aa49c315ffd52fd2d3a4929694909fe65af637b65482b SHA512 4ee297b556d3b555b6ca9f5eb5cc87425b782491d0550a75873aac0f7019b123f437f0731c85bb058fc65b50a589d54d0697657a50bef4ac2952e9e40a916b5c
+DIST libsecret-0.18.6.tar.xz 487836 BLAKE2B d38a41743142d33e634d77bbf55ccab044def9658b3f50bd3f8cec9be6372ad1a56dcc4de58126cba1246c16da2863c003bf14ea6c8a90d8667658cf492f4b9a SHA512 4997519762f1470cfc0a4b3a791362d030af3c9b6ce6f58f8f8073b3a8adeea9b8caacedc884163997081dc39f395f9172330dbb41fed45d6c43ac5809de48e3
diff --git a/app-crypt/libsecret/libsecret-0.18.6.ebuild b/app-crypt/libsecret/libsecret-0.18.6.ebuild
new file mode 100644
index 000000000000..d482aa445539
--- /dev/null
+++ b/app-crypt/libsecret/libsecret-0.18.6.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+GCONF_DEBUG="yes"
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+VALA_USE_DEPEND=vapigen
+
+inherit gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="GObject library for accessing the freedesktop.org Secret Service API"
+HOMEPAGE="https://wiki.gnome.org/Projects/Libsecret"
+
+LICENSE="LGPL-2.1+ Apache-2.0" # Apache-2.0 license is used for tests only
+SLOT="0"
+
+IUSE="+crypt +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	crypt? ( >=dev-libs/libgcrypt-1.2.2:0= )
+	introspection? ( >=dev-libs/gobject-introspection-1.29:= )
+"
+PDEPEND=">=gnome-base/gnome-keyring-3
+"
+# PDEPEND to avoid circular dep (bug #547456)
+# gnome-keyring needed at runtime as explained at https://bugs.gentoo.org/475182#c2
+# Add ksecrets to PDEPEND when it's added to portage
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.35.0
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? (
+		$(python_gen_any_dep '
+			dev-python/mock[${PYTHON_USEDEP}]
+			introspection? ( dev-python/pygobject:3[${PYTHON_USEDEP}] )')
+		introspection? ( >=dev-libs/gjs-1.32 )
+	)
+	vala? ( $(vala_depend) )
+"
+
+python_check_deps() {
+	if use introspection; then
+		has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" || return
+	fi
+	has_version "dev-python/mock[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--enable-manpages \
+		--disable-strict \
+		--disable-coverage \
+		--disable-static \
+		$(use_enable crypt gcrypt) \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}
+
+src_test() {
+	Xemake check
+}