dev-lang/swi-prolog: bump development version

Signed-off-by: Keri Harris <keri@gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11

2 files changed, 100 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index 6cac7d1b7617..ca14e1b0f208 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -8,3 +8,4 @@ DIST swipl-7.7.25.tar.gz 10381235 BLAKE2B 97fa29a863142c2b275c6c08b89d6f5cb734f3
 DIST swipl-8.0.0.tar.gz 10352830 BLAKE2B f5ce1c5d0d48b4904a09b16c0b84b3a0c7385d087aeaa5fb1d673014e10a82e89d477ffb193a37f5b1a8db70cc46b8531cb2358ee8927f8f46b7321edc9c6754 SHA512 1a569793c5cbc7c02a81f94ad73f29459bf085d01162b74b1b72c2a52090d882ae0aee0de6363d143c3fac20f2bbb0e74c2f035d3f3114395048fb4a8073ed5a
 DIST swipl-8.0.1.tar.gz 10364104 BLAKE2B 638ce216c361fe0a85d691989894c113714511628cb305ac990a60cc376a3c5d4f373461e0f2ee66df9954913c6fe7c45d4ef2660dd6fed5bca9339c692a9882 SHA512 40ffb9ecf213ae49b397e5a37d6fb90b83fc353a8408662e193e289c87de9e851427f6523061f067050b258ddad1ded157caf8124149c0335203b9bf08e7baf6
 DIST swipl-8.1.0.tar.gz 10353486 BLAKE2B 421bf72b3a1d269d009da99e65b655a21fd100ecee27f98668a65b491bc0befaa6900c0771c685a5a9b8063a973bdc268410660b51cf808d245ca7ce7cc75f4d SHA512 84c92df24054de33bffd535009c0dc6b6dfd734aeb3bb64b99c80e580961f5305e3acae19ab9d24b1fc34c9e1d71b4dfe14b903d5581d110280edd8386e23a3a
+DIST swipl-8.1.1.tar.gz 10378521 BLAKE2B 5753ecb40c7e1877bc369ced28b3e0d13a3ecc1c48a5fe7e8f5bf45a83da1ae7c6ad600c46145c387b0858f38c7868918d972c90ed1f6c0f8bd98f9683098942 SHA512 eeb1a2521e62bfbb64ab3f570d08523acd7587566d91fc821b1683c6f09e7dddcf0d65a26ad18e209f9283ab714b75cccd83201c5b71df042f34c573fd0aa403
diff --git a/dev-lang/swi-prolog/swi-prolog-8.1.1.ebuild b/dev-lang/swi-prolog/swi-prolog-8.1.1.ebuild
new file mode 100644
index 000000000000..b986aa50d899
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.1.1.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	EPATCH_FORCE=yes
+	EPATCH_SUFFIX=patch
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		epatch "${WORKDIR}"/${PV}
+	fi
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+
+	eapply_user
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}