blob: a1629129f1c47342bd1aabf30fd105153a27b359 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
AC_PREREQ([2.60])
AC_INIT([openrc-settingsd], [0])
AC_CONFIG_SRCDIR([src/main.c])
AM_INIT_AUTOMAKE([check-news foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz])
AC_PROG_CC_STDC
AC_USE_SYSTEM_EXTENSIONS
AC_CONFIG_MACRO_DIR([m4])
AM_SILENT_RULES([yes])
LT_INIT([disable-static pic-only])
AC_PREFIX_DEFAULT([/usr])
AC_PROG_MKDIR_P
AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([librt not found])])
PKG_CHECK_MODULES(OPENRC_SETTINGSD,
[gio-unix-2.0 >= 2.30
gio-2.0 >= 2.30
glib-2.0 >= 2.30
dbus-1
polkit-gobject-1
openrc])
AC_SUBST(OPENRC_SETTINGSD_CFLAGS)
AC_SUBST(OPENRC_SETTINGSD_LIBS)
AC_PATH_PROG(GDBUS_CODEGEN, gdbus-codegen)
if test "x$GDBUS_CODEGEN" = x; then
AC_MSG_ERROR([Failed to find gdbus-codegen])
fi
AC_ARG_WITH([rootsbindir], AS_HELP_STRING([--with-rootsbindir=DIR], [root /sbin directory @<:@default=/sbin@:>@]), [], [with_rootsbindir=/sbin])
AC_SUBST([rootsbindir], [$with_rootsbindir])
AC_MSG_CHECKING([dbus interfaces directory])
dbusinterfacesdir=`$PKG_CONFIG --variable=interfaces_dir dbus-1`
if test "x$dbusinterfacesdir" = "x"; then
AC_MSG_ERROR([not found])
else
AC_MSG_RESULT([$dbusinterfacesdir])
fi
AC_SUBST([dbusinterfacesdir])
AC_MSG_CHECKING([dbus system services directory])
dbussystemservicesdir=`$PKG_CONFIG --variable=system_bus_services_dir dbus-1`
if test "x$dbussystemservicesdir" = "x"; then
AC_MSG_ERROR([not found])
else
AC_MSG_RESULT([$dbussystemservicesdir])
fi
AC_SUBST([dbussystemservicesdir])
AC_MSG_CHECKING([polkit actions directory])
polkitactiondir=`$PKG_CONFIG --variable=actiondir polkit-gobject-1`
if test "x$polkitactiondir" = "x"; then
AC_MSG_ERROR([not found])
else
AC_MSG_RESULT([$polkitactiondir])
fi
AC_SUBST([polkitactiondir])
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_FILES([
Makefile
])
AC_OUTPUT
AC_MSG_RESULT([
$PACKAGE $VERSION
=====
prefix: ${prefix}
sysconfdir: ${sysconfdir}
rootsbindir: ${with_rootsbindir}
compiler: ${CC}
cflags: ${CFLAGS}
ldflags: ${LDFLAGS}
])
|