added fcgi and fcgi-gcc4.4.patch

Signed-off-by: Zhang Le <r0bertz@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-libs/fcgi/fcgi-2.4.0-r2.ebuild b/dev-libs/fcgi/fcgi-2.4.0-r2.ebuild
new file mode 100644
index 0000000..4c5cca2
--- /dev/null
+++ b/dev-libs/fcgi/fcgi-2.4.0-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/fcgi/fcgi-2.4.0-r2.ebuild,v 1.9 2008/01/12 20:26:52 grobian Exp $
+
+inherit eutils autotools multilib
+
+DESCRIPTION="FastCGI Developer's Kit"
+HOMEPAGE="http://www.fastcgi.com/"
+SRC_URI="http://www.fastcgi.com/dist/${P}.tar.gz"
+
+LICENSE="FastCGI"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sh sparc x86 ~x86-fbsd"
+IUSE="html"
+
+DEPEND=""
+RDEPEND=""
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${P}-Makefile.patch"
+	epatch "${FILESDIR}/${P}-clientdata-pointer.patch"
+	epatch "${FILESDIR}/${P}-html-updates.patch"
+	epatch "${FILESDIR}/${PN}-gcc4.4.patch"
+
+	eautoreconf
+}
+
+src_compile() {
+	econf || die "econf failed"
+	make || die "make failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install LIBRARY_PATH="${D}/usr/$(get_libdir)" || die
+
+	dodoc README
+
+	# install the manpages into the right place
+	doman doc/*.[13]
+
+	# Only install the html documentation if USE=html
+	if use html ; then
+		dohtml "${S}"/doc/*/*
+		insinto /usr/share/doc/${PF}/html
+		doins -r "${S}/images"
+	fi
+
+	# install examples in the right place
+	insinto /usr/share/doc/${PF}/examples
+	doins "${S}/examples/"*.c
+}