blob: 2c633ddefdf962503f0b77fd414fcd3de312c32a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
ECM_HANDBOOK="forceoptional"
ECM_TEST="true"
PVCUT=$(ver_cut 1-3)
KFMIN=5.63.0
QTMIN=5.12.3
inherit ecm kde.org
DESCRIPTION="Image viewer by KDE"
HOMEPAGE="https://kde.org/applications/graphics/org.kde.gwenview
https://userbase.kde.org/Gwenview"
LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
SLOT="5"
KEYWORDS=""
IUSE="activities fits kipi +mpris raw semantic-desktop share X"
# requires running environment
RESTRICT+=" test"
COMMON_DEPEND="
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/kitemmodels-${KFMIN}:5
>=kde-frameworks/kitemviews-${KFMIN}:5
>=kde-frameworks/kjobwidgets-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/kparts-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=kde-frameworks/solid-${KFMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtopengl-${QTMIN}:5
>=dev-qt/qtprintsupport-${QTMIN}:5
>=dev-qt/qtsvg-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
media-gfx/exiv2:=
media-libs/lcms:2
media-libs/libpng:0=
media-libs/phonon[qt5(+)]
virtual/jpeg:0
activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
fits? ( sci-libs/cfitsio )
kipi? ( >=kde-apps/libkipi-${PVCUT}:5= )
mpris? ( >=dev-qt/qtdbus-${QTMIN}:5 )
raw? ( >=kde-apps/libkdcraw-${PVCUT}:5 )
semantic-desktop? (
>=kde-frameworks/baloo-${KFMIN}:5
>=kde-frameworks/kfilemetadata-${KFMIN}:5
)
share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
X? (
>=dev-qt/qtx11extras-${QTMIN}:5
x11-libs/libX11
)
"
DEPEND="${COMMON_DEPEND}
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=dev-qt/qtconcurrent-${QTMIN}:5
"
RDEPEND="${COMMON_DEPEND}
>=kde-frameworks/kimageformats-${KFMIN}:5
>=dev-qt/qtimageformats-${QTMIN}:5
kipi? ( >=kde-apps/kipi-plugins-${PVCUT}:5 )
"
src_prepare() {
ecm_src_prepare
if ! use mpris; then
# FIXME: upstream a better solution
sed -e "/set(HAVE_QTDBUS/s/\${Qt5DBus_FOUND}/0/" -i CMakeLists.txt || die
fi
}
src_configure() {
local mycmakeargs=(
$(cmake-utils_use_find_package activities KF5Activities)
$(cmake-utils_use_find_package fits CFitsio)
$(cmake-utils_use_find_package kipi KF5Kipi)
$(cmake-utils_use_find_package raw KF5KDcraw)
$(cmake-utils_use_find_package share KF5Purpose)
$(cmake-utils_use_find_package X X11)
)
if use semantic-desktop; then
mycmakeargs+=( -DGWENVIEW_SEMANTICINFO_BACKEND=Baloo )
else
mycmakeargs+=( -DGWENVIEW_SEMANTICINFO_BACKEND=None )
fi
ecm_src_configure
}
pkg_postinst() {
ecm_pkg_postinst
if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version kde-apps/svgpart:${SLOT} ; then
elog "For SVG support, install kde-apps/svgpart:${SLOT}"
fi
}
|
GitWeb