blob: 7b8925f3fee81b686fd6e9148b06228186b65b9c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
KDE_TESTS=true
VIRTUALDBUS_TEST=true
inherit kde5
DESCRIPTION="Storage service for PIM data"
HOMEPAGE="https://pim.kde.org/akonadi"
KEYWORDS="~amd64 ~x86"
LICENSE="LGPL-2.1"
IUSE="+mysql postgres sqlite test"
REQUIRED_USE="|| ( sqlite mysql postgres )"
CDEPEND="
dev-qt/qtdbus:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtsql:5[mysql?,postgres?]
dev-qt/qttest:5
dev-qt/qtwidgets:5
dev-qt/qtxml:5
x11-misc/shared-mime-info
sqlite? ( dev-db/sqlite:3 )
"
DEPEND="${CDEPEND}
dev-libs/libxslt
test? ( sys-apps/dbus )
"
RDEPEND="${CDEPEND}
mysql? ( virtual/mysql )
postgres? ( dev-db/postgresql )
!app-office/akonadi-server
"
PATCHES=( "${FILESDIR}/${PN}-15.12-mysql56-crash.patch" )
pkg_setup() {
# Set default storage backend in order: MySQL, SQLite PostgreSQL
# reverse driver check to keep the order
if use postgres; then
DRIVER="QPSQL"
AVAILABLE+=" ${DRIVER}"
fi
if use sqlite; then
DRIVER="QSQLITE3"
AVAILABLE+=" ${DRIVER}"
fi
if use mysql; then
DRIVER="QMYSQL"
AVAILABLE+=" ${DRIVER}"
fi
# Notify about MySQL is recommend by upstream
if use sqlite || has_version "<${CATEGORY}/${P}[sqlite]"; then
ewarn
ewarn "We strongly recommend you change your Akonadi database backend to MySQL in your"
ewarn "user configuration. This is the backend recommended by KDE upstream."
ewarn "In particular, kde-apps/kmail-4.10 does not work properly with the sqlite"
ewarn "backend anymore."
ewarn "You can select the backend in your ~/.config/akonadi/akonadiserverrc."
ewarn "Available drivers are:${AVAILABLE}"
ewarn
fi
}
src_configure() {
local mycmakeargs=(
-DKDE_INSTALL_USE_QT_SYS_PATHS=ON
-DAKONADI_BUILD_QSQLITE=$(usex sqlite)
)
kde5_src_configure
}
src_install() {
# Who knows, maybe it accidentally fixes our permission issues
cat <<-EOF > "${T}"/akonadiserverrc
[%General]
Driver=${DRIVER}
EOF
insinto /usr/share/config/akonadi
doins "${T}"/akonadiserverrc
kde5_src_install
}
pkg_postinst() {
elog "${DRIVER} has been set as your default akonadi storage backend."
elog "You can override it in your ~/.config/akonadi/akonadiserverrc."
elog "Available drivers are: ${AVAILABLE}"
}
|
GitWeb