kde-plasma/plasma-firewall: 5.25.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
new file mode 100644
index 0000000000..6e3ff163f7
--- /dev/null
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -0,0 +1 @@
+DIST plasma-firewall-5.25.90.tar.xz 358344 BLAKE2B 60d85fdb6d4355607cf2eb00a1bb923e2f6a5c0e5cd4dc2a56c0e4ea8d87699303669b5f3e30be9f4679574f3bf20078ea749809e5d3a07294c7568ec7f34fa3 SHA512 5e50eb8d2f9c3569dea3dd1ab387d54f216480413504c48f1d39f0a99b95aab3b38a17445d4358f69f4024f4dc044fae2fa36aec037211e790324b7a5c2baa96
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.25.90.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.25.90.ebuild
new file mode 100644
index 0000000000..6523986c69
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.25.90.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+KFMIN=5.98.0
+QTMIN=5.15.5
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}