kde-apps/ksystemlog: 21.08.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/kde-apps/ksystemlog/Manifest b/kde-apps/ksystemlog/Manifest
new file mode 100644
index 0000000000..83c188bdfb
--- /dev/null
+++ b/kde-apps/ksystemlog/Manifest
@@ -0,0 +1 @@
+DIST ksystemlog-21.08.3.tar.xz 1964344 BLAKE2B b07979b7cea394bf264c6a6c3196c87253057c619f0d30f4df58c67fe7ab19adc74dc57ff51e6e7135ea2936f061948973876ab9ffca7efbf06c43ef56661a29 SHA512 ed86c7bac5ce5441bbd5aef6b72687e6472f355cf0a26550e1fe5d1acea29d5970952f0e10b730b17d02f50b8e64a2c742cff8d93af1f839b02bd4512803cdd4
diff --git a/kde-apps/ksystemlog/ksystemlog-21.08.3.ebuild b/kde-apps/ksystemlog/ksystemlog-21.08.3.ebuild
new file mode 100644
index 0000000000..7e5ce2433e
--- /dev/null
+++ b/kde-apps/ksystemlog/ksystemlog-21.08.3.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=5.84.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="System log viewer by KDE"
+HOMEPAGE="https://apps.kde.org/ksystemlog/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="audit kdesu systemd"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	audit? ( sys-process/audit )
+	systemd? ( sys-apps/systemd )
+"
+RDEPEND="${DEPEND}
+	kdesu? ( kde-plasma/kde-cli-tools[kdesu] )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use kdesu; then
+		sed -e "/^X-KDE-SubstituteUID/s:true:false:" \
+			-i src/org.kde.ksystemlog.desktop || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package audit Audit)
+		$(cmake_use_find_package systemd Journald)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	use kdesu || elog "Will show only user readable logs without USE=kdesu (only in X)."
+	use kdesu && elog "Cannot be launched from application menu in Wayland with USE=kdesu."
+}