kde-apps/kleopatra: 22.08.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/kde-apps/kleopatra/Manifest b/kde-apps/kleopatra/Manifest
new file mode 100644
index 0000000000..8aa909878f
--- /dev/null
+++ b/kde-apps/kleopatra/Manifest
@@ -0,0 +1 @@
+DIST kleopatra-22.08.1.tar.xz 2377672 BLAKE2B b5a94222ec131ddbc5102d487c34b02c85bc1daa41953325ac5ff7ac2f672160ffc34120fdb4b7a22a828b159fa962a653535ed43036d632dac0bebf913656c8 SHA512 eb3cf392dd8dc874dd5b883b2ff04ef513c4a06d5f3e97f1356d0d7a496866fcfc5136f5fcedc5c34db1285b12c8dfc72d4137cf97c191b6792b265df4083ab9
diff --git a/kde-apps/kleopatra/kleopatra-22.08.1.ebuild b/kde-apps/kleopatra/kleopatra-22.08.1.ebuild
new file mode 100644
index 0000000000..9a811c96d9
--- /dev/null
+++ b/kde-apps/kleopatra/kleopatra-22.08.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.96.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org
+
+DESCRIPTION="Certificate manager and GUI for OpenPGP and CMS cryptography"
+HOMEPAGE="https://apps.kde.org/kleopatra/"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="pim"
+
+# tests completely broken, bug #641720
+RESTRICT="test"
+
+DEPEND="
+	>=app-crypt/gpgme-1.16.0:=[cxx,qt5]
+	dev-libs/libassuan
+	dev-libs/libgpg-error
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/kmime-${PVCUT}:5
+	>=kde-apps/libkleo-${PVCUT}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	pim? (
+		>=kde-apps/kidentitymanagement-${PVCUT}:5
+		>=kde-apps/kmailtransport-${PVCUT}:5
+	)
+"
+RDEPEND="${DEPEND}
+	>=app-crypt/gnupg-2.1
+	app-crypt/paperkey
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package pim KF5IdentityManagement)
+		$(cmake_use_find_package pim KF5MailTransport)
+		$(cmake_use_find_package pim KF5MailTransportAkonadi)
+	)
+	ecm_src_configure
+}