kde-apps/kate: 22.08.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 66 insertions, 0 deletions

diff --git a/kde-apps/kate/Manifest b/kde-apps/kate/Manifest
new file mode 100644
index 0000000000..bfc2813134
--- /dev/null
+++ b/kde-apps/kate/Manifest
@@ -0,0 +1 @@
+DIST kate-22.08.2.tar.xz 7665324 BLAKE2B af69b60eb16c2e15eeb4300645b3be88347a27dfc9f44aedc286bf50c00be5c146befb4b86fecb6bb470d0a1b7026aa0ed9e5e9292a62cdb90c1e1838086c55d SHA512 09646e70b2a8594f2122864e7c047ce82dbf2ea33e91923171685e220021f3d1b7d8d776a58ec5f3bea564b9fb83fc98f93a5e7910a2f77599756c9f3a949343
diff --git a/kde-apps/kate/kate-22.08.2.ebuild b/kde-apps/kate/kate-22.08.2.ebuild
new file mode 100644
index 0000000000..4756b80fd7
--- /dev/null
+++ b/kde-apps/kate/kate-22.08.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+KFMIN=5.96.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm flag-o-matic gear.kde.org
+
+DESCRIPTION="Multi-document editor with network transparency, Plasma integration and more"
+HOMEPAGE="https://kate-editor.org/ https://apps.kde.org/kate/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	~kde-apps/kate-lib-${PV}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	~kde-apps/kate-addons-${PV}:5
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# these tests are run in kde-apps/kate-lib
+	cmake_run_in apps/lib cmake_comment_add_subdirectory autotests
+
+	# delete colliding kwrite translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		rm -f po/*/*.po || die # installed by kde-apps/kate-lib
+		rm -rf po/*/docs/kwrite || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_addons=FALSE
+		-DBUILD_kwrite=FALSE
+	)
+
+	# provided by kde-apps/kate-lib
+	append-libs -lkateprivate
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# provided by kde-apps/kate-lib
+	rm -v "${ED}"/usr/$(get_libdir)/libkateprivate.so.* || die
+}