kde-apps/kalarm: Add 23.04 stable branch

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 89 insertions, 0 deletions

diff --git a/kde-apps/kalarm/kalarm-23.04.49.9999.ebuild b/kde-apps/kalarm/kalarm-23.04.49.9999.ebuild
new file mode 100644
index 0000000000..1a59eda588
--- /dev/null
+++ b/kde-apps/kalarm/kalarm-23.04.49.9999.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.104.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Application to manage alarms and other timer based alerts for the desktop"
+HOMEPAGE="https://apps.kde.org/kalarm/ https://userbase.kde.org/KAlarm"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+SLOT="5"
+KEYWORDS=""
+IUSE="+pim speech X"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/kcalutils-${PVCUT}:5
+	>=kde-apps/kidentitymanagement-${PVCUT}:5
+	>=kde-apps/kmime-${PVCUT}:5
+	>=kde-apps/kontactinterface-${PVCUT}:5
+	>=kde-apps/kpimtextedit-${PVCUT}:5[speech?]
+	>=kde-apps/pimcommon-${PVCUT}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcalendarcore-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcontacts-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/kholidays-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5[X?]
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=media-libs/phonon-4.11.0
+	pim? (
+		>=kde-apps/akonadi-${PVCUT}:5
+		>=kde-apps/akonadi-contacts-${PVCUT}:5
+		>=kde-apps/akonadi-mime-${PVCUT}:5
+		>=kde-apps/kmailtransport-${PVCUT}:5
+	)
+	speech? ( dev-libs/ktextaddons:5[speech] )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}
+	pim? ( >=kde-apps/kdepim-runtime-${PVCUT}:5 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_AKONADI_PLUGIN=$(usex pim)
+		$(cmake_use_find_package speech KF5TextEditTextToSpeech)
+		-DWITHOUT_X11=$(usex !X)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# LC_TIME bug 665626, 857012
+	# TZ bug https://bugs.kde.org/show_bug.cgi?id=445734
+	LC_TIME="C" TZ=UTC ecm_src_test
+}