kde-apps/kalarm: 22.08.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/kde-apps/kalarm/Manifest b/kde-apps/kalarm/Manifest
new file mode 100644
index 0000000000..fd4bbf3ebd
--- /dev/null
+++ b/kde-apps/kalarm/Manifest
@@ -0,0 +1 @@
+DIST kalarm-22.08.1.tar.xz 2365424 BLAKE2B 070b35f82ab17da5f1f1ce8df00df1d49841095c6b448a4afb6b4820cf309088cdf102b0bb7f42b192f88743b09c87fd62fb7dd0548d7f9b8703b6851099aed3 SHA512 29e0f6e1975585926d44140232f49d03bab68a84a1b68f54007bf262e6a62b37936e6c4a6f5ac89f139ebd6083dd467708c8a31119d16be1b06d852e8ac268cf
diff --git a/kde-apps/kalarm/kalarm-22.08.1.ebuild b/kde-apps/kalarm/kalarm-22.08.1.ebuild
new file mode 100644
index 0000000000..441327177a
--- /dev/null
+++ b/kde-apps/kalarm/kalarm-22.08.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.96.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Application to manage alarms and other timer based alerts for the desktop"
+HOMEPAGE="https://apps.kde.org/kalarm/ https://userbase.kde.org/KAlarm"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+pim speech X"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/kcalutils-${PVCUT}:5
+	>=kde-apps/kidentitymanagement-${PVCUT}:5
+	>=kde-apps/kmime-${PVCUT}:5
+	>=kde-apps/kontactinterface-${PVCUT}:5
+	>=kde-apps/kpimtextedit-${PVCUT}:5[speech=]
+	>=kde-apps/pimcommon-${PVCUT}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcalendarcore-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcontacts-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/kholidays-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5[X?]
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=media-libs/phonon-4.11.0
+	pim? (
+		>=kde-apps/akonadi-${PVCUT}:5
+		>=kde-apps/akonadi-contacts-${PVCUT}:5
+		>=kde-apps/akonadi-mime-${PVCUT}:5
+		>=kde-apps/kmailtransport-${PVCUT}:5
+	)
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}
+	!kde-apps/kalarmcal:5
+	pim? ( >=kde-apps/kdepim-runtime-${PVCUT}:5 )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-22.07.90-without_x11.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_AKONADI_PLUGIN=$(usex pim)
+		-DWITHOUT_X11=$(usex !X)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# LC_TIME bug 665626, 857012
+	# TZ bug https://bugs.kde.org/show_bug.cgi?id=445734
+	LC_TIME="C" TZ=UTC ecm_src_test
+}