gnome-base/gvfs-1.9.1.ebuild

Add gnome-3.1.x snapshot, identical to live ebuild. Set EAPI=4 in 1.9.1
and the live ebuild to get xz tarballs.

4 files changed, 124 insertions, 2 deletions

diff --git a/gnome-base/gvfs/Manifest b/gnome-base/gvfs/Manifest
index 42bb9b71..c54217ea 100644
--- a/gnome-base/gvfs/Manifest
+++ b/gnome-base/gvfs/Manifest
@@ -1,5 +1,7 @@
 AUX gvfs-1.2.2-expose-archive-backend.patch 1607 RMD160 cd17c501805fb81e560c35deb1d234280fd07f5c SHA1 70b1824a49ba654dda5ae2ef267ca45a31b53dc4 SHA256 a6cd0f6b848e1943f9121cf4ce4105f32573f9cf7cf75bc0d7d61a98babec519
 AUX gvfs-1.2.2-gphoto2-stricter-checks.patch 1127 RMD160 0c6d83f8b38cf41002dbe6f863916cfac66cd231 SHA1 fc4927fc0f3604689d446d4fe47b48384bee70a5 SHA256 146349147b82721551ce717d892068d608b352fdabd40b969ec9c2b97595c062
 DIST gvfs-1.8.2.tar.bz2 1413675 RMD160 3163a9fe5452904bdef804cfb0698c6deec86eea SHA1 4123bb4fd9d64f246adc8f3b6a00af12589cd37b SHA256 0895ac8f6d416e1b15433b6b6b68eb119c6e8b04fdb66db665d684355ef89345
+DIST gvfs-1.9.1.tar.xz 1209044 RMD160 573343802ea51057d00cf84e36b303c3498ffb54 SHA1 f476510a820bf461a1a72df706a8f1357a9499c6 SHA256 1cdcc1953e4994bea04b0bd57c47bb7d5f402f4de712379718c9352e16818368
 EBUILD gvfs-1.8.2-r1.ebuild 3341 RMD160 f0a1ae2949d83b1ae7ecc3563388eb71f9e7c65a SHA1 fb5feb34a74979865bc1fa83d130f510f0b9ed3e SHA256 dcca1f1c4b7561605f47639b3cd9e7e60be2fd4ce425eaf3abf2b682af98c310
-EBUILD gvfs-9999.ebuild 3341 RMD160 f0a1ae2949d83b1ae7ecc3563388eb71f9e7c65a SHA1 fb5feb34a74979865bc1fa83d130f510f0b9ed3e SHA256 dcca1f1c4b7561605f47639b3cd9e7e60be2fd4ce425eaf3abf2b682af98c310
+EBUILD gvfs-1.9.1.ebuild 3341 RMD160 efebccfddef80d1bd4f47b2ce62a820d4593b143 SHA1 671450b7dc6b3dccf854e3aa26607d1f4d755208 SHA256 4a324f34331608530714ba973fe97263cfcb768c21a979de161608ec719e197c
+EBUILD gvfs-9999.ebuild 3341 RMD160 efebccfddef80d1bd4f47b2ce62a820d4593b143 SHA1 671450b7dc6b3dccf854e3aa26607d1f4d755208 SHA256 4a324f34331608530714ba973fe97263cfcb768c21a979de161608ec719e197c
diff --git a/gnome-base/gvfs/gvfs-1.9.1.ebuild b/gnome-base/gvfs/gvfs-1.9.1.ebuild
new file mode 100644
index 00000000..11013b75
--- /dev/null
+++ b/gnome-base/gvfs/gvfs-1.9.1.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/gvfs-1.6.4-r1.ebuild,v 1.1 2010/10/05 08:49:12 pacho Exp $
+
+EAPI="4"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit autotools bash-completion gnome2 eutils
+if [[ ${PV} = 9999 ]]; then
+	inherit gnome2-live
+fi
+
+DESCRIPTION="GNOME Virtual Filesystem Layer"
+HOMEPAGE="http://www.gnome.org"
+
+LICENSE="LGPL-2"
+SLOT="0"
+if [[ ${PV} = 9999 ]]; then
+	KEYWORDS=""
+	DOCS="AUTHORS ChangeLog.pre-1-2 NEWS README TODO"
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+	DOCS="AUTHORS ChangeLog ChangeLog.pre-1-2 NEWS README TODO"
+fi
+IUSE="archive avahi bluetooth cdda doc fuse gdu gnome-keyring gphoto2 +http ios prefix samba +udev"
+
+RDEPEND=">=dev-libs/glib-2.27.4
+	>=sys-apps/dbus-1.0
+	dev-libs/libxml2
+	net-misc/openssh
+	!prefix? ( >=sys-fs/udev-138 )
+	archive? ( app-arch/libarchive )
+	avahi? ( >=net-dns/avahi-0.6 )
+	bluetooth? (
+		>=app-mobilephone/obex-data-server-0.4.5
+		dev-libs/dbus-glib
+		net-wireless/bluez
+		dev-libs/expat )
+	fuse? ( >=sys-fs/fuse-2.8.0 )
+	gdu? ( >=sys-apps/gnome-disk-utility-2.29 )
+	gnome-keyring? ( >=gnome-base/gnome-keyring-1.0 )
+	gphoto2? ( >=media-libs/libgphoto2-2.4.7 )
+	ios? (
+		>=app-pda/libimobiledevice-1.1.0
+		>=app-pda/libplist-0.15 )
+	udev? (
+		cdda? ( >=dev-libs/libcdio-0.78.2[-minimal] )
+		|| ( >=sys-fs/udev-171[gudev] >=sys-fs/udev-145[extras] ) )
+	http? ( >=net-libs/libsoup-gnome-2.26.0 )
+	samba? ( || ( >=net-fs/samba-3.4.6[smbclient]
+			<=net-fs/samba-3.3 ) )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	>=dev-util/pkgconfig-0.19
+	dev-util/gtk-doc-am
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+pkg_setup() {
+	if use cdda && ! use udev; then
+		ewarn
+		ewarn "You need to enable USE=\"udev\" for USE=\"cdda\" to be useful."
+		ewarn
+	fi
+
+	G2CONF="${G2CONF}
+		--disable-bash-completion
+		--disable-hal
+		--disable-schemas-compile
+		--with-dbus-service-dir=/usr/share/dbus-1/services
+		$(use_enable archive)
+		$(use_enable avahi)
+		$(use_enable bluetooth obexftp)
+		$(use_enable cdda)
+		$(use_enable fuse)
+		$(use_enable gdu)
+		$(use_enable gphoto2)
+		$(use_enable ios afc)
+		$(use_enable udev gudev)
+		$(use_enable http)
+		$(use_enable gnome-keyring keyring)
+		$(use_enable samba)
+		$(use_enable !prefix udev)"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Conditional patching purely to avoid eautoreconf
+	use gphoto2 && epatch "${FILESDIR}/${PN}-1.2.2-gphoto2-stricter-checks.patch"
+
+	if use archive; then
+		epatch "${FILESDIR}/${PN}-1.2.2-expose-archive-backend.patch"
+		echo "mount-archive.desktop.in" >> po/POTFILES.in
+		echo "mount-archive.desktop.in.in" >> po/POTFILES.in
+	fi
+
+	if use prefix; then
+		sed -i -e 's/gvfsd-burn/ /' daemon/Makefile.am || die
+		sed -i -e 's/burn.mount.in/ /' daemon/Makefile.am || die
+		sed -i -e 's/burn.mount/ /' daemon/Makefile.am || die
+	fi
+
+	{ use gphoto2 || use archive || use prefix; } && eautoreconf
+}
+
+src_install() {
+	gnome2_src_install
+	use bash-completion && \
+		dobashcompletion programs/gvfs-bash-completion.sh ${PN}
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	use bash-completion && bash-completion_pkg_postinst
+
+	ewarn "In order to use the new gvfs services, please reload dbus configuration"
+	ewarn "You may need to log out and log back in for some changes to take effect"
+}
diff --git a/gnome-base/gvfs/gvfs-9999.ebuild b/gnome-base/gvfs/gvfs-9999.ebuild
index 92d740b6..11013b75 100644
--- a/gnome-base/gvfs/gvfs-9999.ebuild
+++ b/gnome-base/gvfs/gvfs-9999.ebuild
@@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 # $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/gvfs-1.6.4-r1.ebuild,v 1.1 2010/10/05 08:49:12 pacho Exp $
 
-EAPI="3"
+EAPI="4"
 GCONF_DEBUG="no"
 GNOME2_LA_PUNT="yes"
 
diff --git a/profiles/package.mask b/profiles/package.mask
index 19556a89..96271705 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -12,6 +12,7 @@
 =dev-libs/glib-2.29*
 =dev-libs/gobject-introspection-1*
 =gnome-base/gnome-desktop-3.1*
+=gnome-base/gvfs-1.9*
 =media-libs/cogl-1.7*
 =media-libs/clutter-1.7*
 =x11-libs/gtk+-3.1*