app-text/atril: version bump to 1.16.1

* update live ebuild dependencies

Package-Manager: portage-2.3.1

3 files changed, 97 insertions, 1 deletions

diff --git a/app-text/atril/Manifest b/app-text/atril/Manifest
index 6363192..4d3fbcb 100644
--- a/app-text/atril/Manifest
+++ b/app-text/atril/Manifest
@@ -1,2 +1,3 @@
 DIST atril-1.12.2.tar.xz 1663920 SHA256 47cd22969d4ff6ef860a310a57f77f1fcc0c5674113a72ee507d2b1b5c780226 SHA512 2ceeda42adeb284a25caff3a69d15a231129988fb410e4d502a281ccf5819307b9963722a2e330307a1c3b15d3c82405b708d983ed1c266e091a35264766e6ec WHIRLPOOL 8eb8a0cd40c0c3d21141493a09b3dc8f2c4d902fff1ed80fe5468b1ac342c81312518c015cbd288372f228bc4bb91bb1555af8f8b5842e72e4eb895fc787988c
 DIST atril-1.14.2.tar.xz 1703272 SHA256 9a8eadd85bda4539560f01a2127be4d6c358c07c6a744c09d1fdb5bff7ce14f4 SHA512 9f77abe43848a3a35df1484edef4a6bbc6339f82b0d8e9f3c149c44fd632f2720acf24bcc1354b944c5c364fc4ce1d70b733c1ec5bc40b1a17041e59acf7bd9b WHIRLPOOL 3e4bf2f6af6369b7cf410f161c159f6f0221d311b354c24d8b86fbcb14c3553d01ea6d79667d9817541aa401202bc8590d074f635745730854a148ca74b41dfc
+DIST atril-1.16.1.tar.xz 1691456 SHA256 c74a5f8c8603fa5952efb4343f055677e4474f1907080be9658d4456d3dc092f SHA512 69128171f13f50079b0b40bfada868967c289b5970e3cda3454f10e7cf723000ab29290c7c9ada67648c370472fd51eeb0a8dbbfa0af05babfc85cb28e3570fe WHIRLPOOL a7b386897c598e473642aa8c3ba2a40211c4389ef3560e574adf04072882887e37a50a7d83ff5fab4c74982908994c926211272d33220fb47a360e05c851a670
diff --git a/app-text/atril/atril-1.16.1.ebuild b/app-text/atril/atril-1.16.1.ebuild
new file mode 100644
index 0000000..de33444
--- /dev/null
+++ b/app-text/atril/atril-1.16.1.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MATE_LA_PUNT="yes"
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+DESCRIPTION="Atril document viewer for MATE"
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="caja dbus debug djvu dvi epub +introspection gnome-keyring gtk3 +postscript t1lib tiff xps"
+
+REQUIRED_USE="t1lib? ( dvi )"
+
+COMMON_DEPEND=">=app-text/poppler-0.22:0=[cairo]
+	dev-libs/atk:0
+	>=dev-libs/glib-2.36:2
+	>=dev-libs/libxml2-2.5:2
+	sys-libs/zlib:0
+	x11-libs/gdk-pixbuf:2
+	x11-libs/libICE:0
+	>=x11-libs/libSM-1:0
+	x11-libs/libX11:0
+	>=x11-libs/cairo-1.9.10:0
+	x11-libs/pango:0
+	caja? ( >=mate-base/caja-1.8[gtk3(-)=,introspection?] )
+	djvu? ( >=app-text/djvu-3.5.17:0 )
+	dvi? (
+		virtual/tex-base:0
+		t1lib? ( >=media-libs/t1lib-5:5 )
+	)
+	epub? ( dev-libs/mathjax )
+	gnome-keyring? ( >=app-crypt/libsecret-0.5:0 )
+	!gtk3? (
+		>=x11-libs/gtk+-2.24.0:2[introspection?]
+		epub? ( >=net-libs/webkit-gtk-2.4.3:2 )
+	)
+	gtk3? (
+		>=x11-libs/gtk+-3.0:3[introspection?]
+		epub? ( >=net-libs/webkit-gtk-2.4.3:4 )
+	)
+	introspection? ( >=dev-libs/gobject-introspection-0.6:= )
+	postscript? ( >=app-text/libspectre-0.2:0 )
+	tiff? ( >=media-libs/tiff-3.6:0 )
+	xps? ( >=app-text/libgxps-0.2.1:0 )
+	!!app-text/mate-document-viewer"
+
+RDEPEND="${COMMON_DEPEND}"
+
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	app-text/rarian:0
+	app-text/yelp-tools:0
+	>=app-text/scrollkeeper-dtd-1:1.0
+	dev-util/gtk-doc
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.50.1:*
+	virtual/pkgconfig:*
+	sys-devel/gettext:*"
+
+# Tests use dogtail which is not available on Gentoo.
+RESTRICT="test"
+
+src_configure() {
+	# Passing --disable-help would drop offline help, that would be inconsistent
+	# with helps of the most of GNOME apps that doesn't require network for that.
+	mate_src_configure \
+		--disable-tests \
+		--enable-comics \
+		--enable-pdf \
+		--enable-pixbuf \
+		--enable-previewer \
+		--enable-thumbnailer \
+		--with-gtk=$(usex gtk3 3.0 2.0) \
+		$(use_with gnome-keyring keyring) \
+		$(use_enable caja) \
+		$(use_enable dbus) \
+		$(use_enable debug) \
+		$(use_enable djvu) \
+		$(use_enable dvi) \
+		$(use_enable epub) \
+		$(use_enable introspection) \
+		$(use_enable postscript ps) \
+		$(use_enable t1lib) \
+		$(use_enable tiff) \
+		$(use_enable xps)
+}
diff --git a/app-text/atril/atril-9999.ebuild b/app-text/atril/atril-9999.ebuild
index c87c15c..de33444 100644
--- a/app-text/atril/atril-9999.ebuild
+++ b/app-text/atril/atril-9999.ebuild
@@ -20,7 +20,7 @@ IUSE="caja dbus debug djvu dvi epub +introspection gnome-keyring gtk3 +postscrip
 
 REQUIRED_USE="t1lib? ( dvi )"
 
-COMMON_DEPEND=">=app-text/poppler-0.18:0=[cairo]
+COMMON_DEPEND=">=app-text/poppler-0.22:0=[cairo]
 	dev-libs/atk:0
 	>=dev-libs/glib-2.36:2
 	>=dev-libs/libxml2-2.5:2