media-libs/elementary/elementary-1.9.0_beta2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit eutils

DESCRIPTION="Basic widget set, based on EFL for mobile touch-screen devices."
HOMEPAGE="http://trac.enlightenment.org/e/wiki/Elementary"
SRC_URI="http://download.enlightenment.org/rel/libs/${PN}/${P/_/-}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="X debug doc examples fbcon nls quicklaunch sdl static-libs test wayland"

RDEPEND="
	>=dev-libs/efl-1.9.0_beta2[X?,fbcon?,png,sdl?,wayland?]
	nls? ( sys-devel/gettext )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	test? ( >=dev-libs/check-0.9.5 )"

S="${WORKDIR}/${P/_/-}"

src_configure() {
	local config=(
		$(use_enable X ecore-x)
		$(use_enable fbcon ecore-fb)
		$(use_enable sdl ecore-sdl)
		$(use_enable wayland ecore-wayland)
		--disable-ecore-cocoa
		--disable-ecore-psl1ght
		--disable-ecore-win32
		--disable-ecore-wince

		$(use_enable debug)
		$(use_enable doc)
		$(use_enable examples build-examples)
		$(use_enable examples install-examples)
		$(use_enable nls)
		$(use_enable static-libs static)
		$(use_enable quicklaunch quick-launch)
		--disable-elocation
		--disable-emap
		--disable-eweather

		--with-tests=$(usex test regular none)

		--with-elementary-web-backend=none
	)

	econf "${config[@]}"
}

src_install() {
	default
	prune_libtool_files
}