dev-ruby/rack-mini-profiler/rack-mini-profiler-3.3.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8
USE_RUBY="ruby31 ruby32"

RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
RUBY_FAKEGEM_GEMSPEC="rack-mini-profiler.gemspec"
RUBY_FAKEGEM_RECIPE_TEST="rspec3"

inherit ruby-fakegem

DESCRIPTION="Profiling toolkit for Rack applications with Rails integration"
HOMEPAGE="https://miniprofiler.com/"
SRC_URI="https://github.com/MiniProfiler/rack-mini-profiler/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"

KEYWORDS="~amd64"
SLOT="0"

ruby_add_rdepend "
	>=dev-ruby/rack-1.2.0:*
"

ruby_add_bdepend "test? ( dev-ruby/rack:2.2 dev-ruby/rack-test )"

all_ruby_prepare() {
	sed -i -e '/bundler/I s:^:#:' Rakefile || die

	# Avoid specs depending on external running dependencies
	rm -f spec/lib/storage/{memcache,redis}_store_spec.rb || die

	# Avoid webpacker specs since webpacker is obsolete
	sed -e '/get_webpacker_assets_path returns webpacker/ s/it/xit/' \
		-i spec/integration/railtie_methods_spec.rb || die

	# Avoid rack 3 for now
	sed -e '4igem "rack", "~> 2.2.0"' \
		-e '/simplecov/,/^end/ s:^:#:' \
		-i spec/spec_helper.rb || die
}