net-mail/offlineimap3: package move to net-mail category

As its Python 2 based ancestor.

Signed-off-by: Gilles Dartiguelongue <eva@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/net-mail/offlineimap3/metadata.xml b/net-mail/offlineimap3/metadata.xml
new file mode 100644
index 0000000..5a5d6b8
--- /dev/null
+++ b/net-mail/offlineimap3/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<maintainer type="person">
+		<email>eva@gentoo.org</email>
+		<name>Gilles Dartiguelongue</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">EvaSDK/offlineimap3</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/net-mail/offlineimap3/offlineimap3-8.0.0_pre20210322.ebuild b/net-mail/offlineimap3/offlineimap3-8.0.0_pre20210322.ebuild
new file mode 100644
index 0000000..d2f5ffc
--- /dev/null
+++ b/net-mail/offlineimap3/offlineimap3-8.0.0_pre20210322.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_8 )
+PYTHON_REQ_USE="sqlite,ssl?"
+inherit distutils-r1 git-r3
+
+DESCRIPTION="Powerful IMAP/Maildir synchronization and reader support"
+HOMEPAGE="https://github.com/OfflineIMAP/offlineimap3"
+EGIT_REPO_URI="https://github.com/EvaSDK/${PN}.git"
+EGIT_COMMIT="df35e6cedcabf60fdcb9638edd27dbcb71f2112c"
+EGIT_BRANCH="packaging"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc kerberos ssl"
+
+DEPEND="doc? ( app-text/asciidoc )"
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	>=dev-python/imaplib2-2.57[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/rfc6555[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.9[${PYTHON_USEDEP}]
+	kerberos? ( dev-python/gssapi[${PYTHON_USEDEP}] )
+"
+BDEPEND=""
+
+src_prepare() {
+	sed -i "/^__version__/ s/\"\(.*\)\"/\"${PV}\"/" offlineimap/__init__.py
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	distutils-r1_src_compile
+	use doc && emake -C docs man
+}
+
+src_install() {
+	distutils-r1_src_install
+	dodoc offlineimap.conf offlineimap.conf.minimal
+	use doc && doman docs/{offlineimap.1,offlineimapui.7}
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog "You will need to configure offlineimap by creating ~/.offlineimaprc"
+		elog "Sample configurations are in /usr/share/doc/${PF}/"
+		elog ""
+		elog "If you connect via ssl/tls and don't use CA cert checking, it will"
+		elog "display the server's cert fingerprint and require you to add it to the"
+		elog "configuration file to be sure it connects to the same server every"
+		elog "time. This serves to help fixing CVE-2010-4532 (offlineimap doesn't"
+		elog "check SSL server certificate) in cases where you have no CA cert."
+	fi
+}