sys-power/powertop/powertop-1.98.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-power/powertop/powertop-1.98.ebuild,v 1.4 2012/04/19 16:17:48 vapier Exp $

EAPI="4"

inherit eutils toolchain-funcs
if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="git://git.kernel.org/pub/scm/status/powertop/powertop.git"
	inherit git-2
	SRC_URI=""
else
	SRC_URI="mirror://kernel/linux/status/${PN}/${P}.tar.bz2"
	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
fi

DESCRIPTION="tool that helps you find what software is using the most power"
HOMEPAGE="http://www.lesswatts.org/projects/powertop/"

LICENSE="GPL-2"
SLOT="0"
IUSE="unicode"

DEPEND="
	dev-libs/libnl
	sys-apps/pciutils
	sys-devel/gettext
	sys-libs/ncurses[unicode?]
	sys-libs/zlib
"
RDEPEND="
	${DEPEND}
	net-wireless/bluez
	x11-apps/xset
"

DOCS=( TODO README )

src_prepare() {
	use unicode || sed -i 's:-lncursesw:-lncurses:' Makefile
	epatch "${FILESDIR}"/${PN}-1.98-build.patch
	epatch "${FILESDIR}"/${PN}-1.98-build-cc.patch
	epatch "${FILESDIR}"/${PN}-1.98-build-libnl-3.patch
	epatch "${FILESDIR}"/${PN}-1.98-gcc-4.7.patch
}

src_configure() {
	tc-export BUILD_CC CC CXX
}

src_install() {
	default
	keepdir /var/cache/powertop
}

pkg_postinst() {
	echo
	einfo "For PowerTOP to work best, use a Linux kernel with the"
	einfo "tickless idle (NO_HZ) feature enabled (version 2.6.21 or later)"
	echo
}