1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/scipy/scipy-0.12.0.ebuild,v 1.6 2013/09/10 02:43:58 patrick Exp $
EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
inherit eutils fortran-2 distutils-r1 flag-o-matic multilib toolchain-funcs
DESCRIPTION="Scientific algorithms library for Python"
HOMEPAGE="http://www.scipy.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
doc? (
http://docs.scipy.org/doc/${PN}/${PN}-html.zip -> ${P}-html.zip
http://docs.scipy.org/doc/${PN}/${PN}-ref.pdf -> ${P}-ref.pdf
)"
LICENSE="BSD LGPL-2"
SLOT="0"
IUSE="doc sparse test"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
CDEPEND="
dev-python/numpy[lapack,${PYTHON_USEDEP}]
sci-libs/arpack
virtual/cblas
virtual/lapack
sparse? ( sci-libs/umfpack )"
DEPEND="${CDEPEND}
dev-lang/swig
dev-python/cython[${PYTHON_USEDEP}]
virtual/pkgconfig
doc? ( app-arch/unzip )
test? ( dev-python/nose[${PYTHON_USEDEP}] )"
RDEPEND="${CDEPEND}
virtual/python-imaging[${PYTHON_USEDEP}]"
DOCS=( HACKING.rst.txt README.txt THANKS.txt LATEST.txt TOCHANGE.txt )
DISTUTILS_IN_SOURCE_BUILD=1
src_unpack() {
unpack ${P}.tar.gz
if use doc; then
unzip -qo "${DISTDIR}"/${P}-html.zip -d html || die
fi
}
pc_incdir() {
$(tc-getPKG_CONFIG) --cflags-only-I $@ | \
sed -e 's/^-I//' -e 's/[ ]*-I/:/g' -e 's/[ ]*$//'
}
pc_libdir() {
$(tc-getPKG_CONFIG) --libs-only-L $@ | \
sed -e 's/^-L//' -e 's/[ ]*-L/:/g' -e 's/[ ]*$//'
}
pc_libs() {
$(tc-getPKG_CONFIG) --libs-only-l $@ | \
sed -e 's/[ ]-l*\(pthread\|m\)[ ]*//g' \
-e 's/^-l//' -e 's/[ ]*-l/,/g' -e 's/[ ]*$//'
}
python_prepare_all() {
# scipy automatically detects libraries by default
export {FFTW,FFTW3,UMFPACK}=None
use sparse && unset UMFPACK
# the missing symbols are in -lpythonX.Y, but since the version can
# differ, we just introduce the same scaryness as on Linux/ELF
[[ ${CHOST} == *-darwin* ]] \
&& append-ldflags -bundle "-undefined dynamic_lookup" \
|| append-ldflags -shared
[[ -z ${FC} ]] && export FC="$(tc-getFC)"
# hack to force F77 to be FC until bug #278772 is fixed
[[ -z ${F77} ]] && export F77="$(tc-getFC)"
export F90="${FC}"
export SCIPY_FCONFIG="config_fc --noopt --noarch"
append-fflags -fPIC
local libdir="${EPREFIX}"/usr/$(get_libdir)
cat >> site.cfg <<-EOF
[blas]
include_dirs = $(pc_incdir cblas)
library_dirs = $(pc_libdir cblas blas):${libdir}
blas_libs = $(pc_libs cblas blas)
[lapack]
library_dirs = $(pc_libdir lapack):${libdir}
lapack_libs = $(pc_libs lapack)
EOF
local PATCHES=(
"${FILESDIR}"/${P}-gerqf.patch
"${FILESDIR}"/${P}-blitz.patch
"${FILESDIR}"/${P}-restore-sys-argv.patch
"${FILESDIR}"/${P}-cephes-missing-include.patch
)
distutils-r1_python_prepare_all
}
python_compile() {
distutils-r1_python_compile ${SCIPY_FCONFIG}
}
python_test() {
distutils_install_for_testing ${SCIPY_FCONFIG}
cd "${TEST_DIR}" || die "no ${TEST_DIR} available"
# nasty hack to remove weave tests because it is not python3 compat
[[ ${TEST_DIR} =~ python3 ]] && rm -r "${TEST_DIR}"/lib/scipy/weave
#r = scipy.test('full', verbose=10)
"${EPYTHON}" -c "
import scipy, sys
r = scipy.test('fast',verbose=2)
sys.exit(0 if r.wasSuccessful() else 1)" || die "Tests fail with ${EPYTHON}"
}
python_install_all() {
if use doc; then
dohtml -r "${WORKDIR}"/html/.
dodoc "${DISTDIR}"/${P}*pdf
fi
distutils-r1_python_install_all
}
python_install() {
distutils-r1_python_install ${SCIPY_FCONFIG}
}
pkg_postinst() {
elog "You might want to set the variable SCIPY_PIL_IMAGE_VIEWER"
elog "to your prefered image viewer. Example:"
elog "\t echo \"export SCIPY_PIL_IMAGE_VIEWER=display\" >> ~/.bashrc"
}
|
GitWeb