net-libs/libisds/libisds-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libisds/libisds-9999.ebuild,v 1.10 2012/05/05 02:54:26 jdhore Exp $

EAPI=4

[[ ${PV} = 9999* ]] && GIT="git-2 autotools"
EGIT_REPO_URI="git://repo.or.cz/${PN}.git"
inherit autotools-utils ${GIT}

DESCRIPTION="Client library for accessing ISDS Soap services"
HOMEPAGE="http://xpisar.wz.cz/libisds/"
if [[ ${PV} = 9999* ]]; then
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="http://xpisar.wz.cz/${PN}/dist/${P}.tar.xz"
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="LGPL-3"
SLOT="0"
IUSE="+curl debug nls static-libs test"

COMMON_DEPEND="
	app-crypt/gpgme
	dev-libs/expat
	dev-libs/libgcrypt
	dev-libs/libxml2
	curl? ( net-misc/curl[ssl] )
"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig
	nls? ( sys-devel/gettext )
"
RDEPEND="${COMMON_DEPEND}
	>=app-crypt/gnupg-2
"

DOCS=( NEWS README AUTHORS ChangeLog )

src_prepare() {
	[[ ${PV} = 9999* ]] && eautoreconf
}

src_configure() {
	local myeconfargs=(
		"--disable-fatalwarnings"
		$(use_with curl libcurl)
		$(use_enable debug)
		$(use_enable nls)
		$(use_enable static-libs static)
		$(use_enable test)
	)

	autotools-utils_src_configure
}